PowerBI -删除0值的初始记录

Question

我在PowerBI中有一张桌子，如下所示：

Date           StoreID       Car Sales     <Row Num (for explanation only)>
1/1/2017       1             0               1
1/2/2017       1             0               2
1/3/2017       1             0               3
1/4/2017       1             20              4 
1/5/2017       1             13              5
1/6/2017       1             0               6
1/7/2017       1             31              7

1/4/2017       2             0               8
1/5/2017       2             0               9
1/6/2017       2             7              10
1/7/2017       2             0              11
1/8/2017       2             10             12

我想要做的是创建一个度量来计算一天的汽车销量(在x轴上有日期的线图上)，但在具有销售价值的第一个日期之前删除0的行/记录。换句话说，我想要删除第1行、第2行和第3行，而不是删除第6行，因为这是一个没有汽车销售的合法日子。我也想对每个StoreID都这样做，所以我想要删除第8行和第9行，而不是第11行。有什么方法可以在PowerBI中找到一个度量/列(或其他方法)来实现这一点吗？

Answer 1

您可以按StoreID进行分组，然后用: sort转换每个列，然后使用Table.Skip删除汽车销量为0的行。(按日期排序似乎没有必要，但按组排序可以更改顺序。)然后展开分组表。

let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Date", type datetime}, {"StoreID", Int64.Type}, {"Car Sales", Int64.Type}}),
    #"Grouped Rows" = Table.Group(#"Changed Type", {"StoreID"}, {{"Grouped", (grouped) => let
            #"Sorted Rows" = Table.Sort(grouped,{{"Date", Order.Ascending}}),
            SkipNoCarSales = Table.Skip(#"Sorted Rows", each [Car Sales] = 0)
        in
            SkipNoCarSales, type table}}),
    #"Expanded Grouped" = Table.ExpandTableColumn(#"Grouped Rows", "Grouped", {"Car Sales", "Date"}, {"Car Sales", "Date"}),
    #"Reordered Columns" = Table.ReorderColumns(#"Expanded Grouped",{"Car Sales", "StoreID", "Date"})
in
    #"Reordered Columns"