用单例判别联合法生成计算表达式

Question

如果我有一个函数，试图将一个起始数除以两次。整个工作流必须返回一个布尔值。

let divideBy bottom top =
    if bottom = 0 then None
    else Some (top/bottom)

let divideByWorkflow init x y = 
    match init |> divideBy x with
    | None -> false
    | Some a -> 
        match a |> divideBy y with
        | None -> false
        | Some b -> true

let good = divideByWorkflow 12 3 2
let bad = divideByWorkflow 12 3 0

下面的生成器是正确的吗？

type BoolMaybe = BoolMaybe with
    member __.Bind (expr, f) =
        match expr with
        | Some value -> f value
        | None -> false
    member __.Return expr = expr

let divideByWorkflow init x y =
    BoolMaybe {
        let! a = init |> divideBy x
        let! b = a |> divideBy y
        return true
    }

Answer 1

我同意Dzoukr的回答，我的回答看起来有点不同：

let divideBy bot top =
    match bot with
    | 0 -> None
    | _ -> Some (top / bot)

let divideByWorkflow init x y =
    Some init
    |> Option.bind (divBy x)
    |> Option.bind (divBy y)
    |> Option.isSome

不需要计算表达式，在这里似乎没有增加任何好处。

Answer 2

IMHO没有理由使用计算表达式使其变得更加复杂。我宁愿呆在几个简单的函数中，比如：

let divideBy bottom top =
    if bottom = 0 then None
    else Some (top/bottom)

let divideByTwoTimes init x y = 
    init |> divideBy x |> Option.bind (divideBy y)

let divideByWorkflow init x = divideByTwoTimes init x >> Option.isSome

Answer 3

很有效，但我认为这是不必要的具体。如果您确实想使用CE，我宁愿定义一个普通的Maybe CE，然后执行

let divideByWorkflow init x y =
    Maybe {
        let! a = init |> divideBy x
        let! b = a |> divideBy y
        return true
    }
    |> Option.defaultValue false