控件-p5-滑块值显示不正确

Question

我有一个处理草图，其中包括一个滑块。生成此滑块的代码如下：

ControlP5 gui;
gui = new ControlP5(this);
gui.addSlider("Tolerance").setPosition(40, height-60).setSize(400, 20).setRange(0.00, 0.10).setValue(0.05).setNumberOfTickMarks(11).setSliderMode(Slider.FLEXIBLE);
gui.getController("Tolerance").getValueLabel().align(ControlP5.RIGHT, ControlP5.TOP_OUTSIDE).setPaddingX(0).setFont(font);
gui.getController("Tolerance").setCaptionLabel("Comparison Tolerance");
gui.getController("Tolerance").getCaptionLabel().align(ControlP5.LEFT, ControlP5.TOP_OUTSIDE).setPaddingX(0).setFont(font);

我遇到的问题是，当滑块同时位于0.08 TickMark和0.09 TickMark时，就会显示值0.09。0.09是唯一不正确显示的值-请参见下面的图片：

​

​

​

​

​

​

​

​

当滑块的位置被打印到控制台时，滑块实际上是在上面的第三个图像中选择0.09的正确值，但是这个显示错误是混乱和不理想的。任何帮助都将不胜感激。

更新：我发现显示在滑块右上角的值总是四舍五入的向下。当将滑块值输出到控制台时，这些值通常与预期值非常不同--即在中心位置，打印到控制台的实际滑块值为0.0500003。从每个滑块位置的真实值来看，0.09位置是唯一一个在预期值- 0.0899996下具有值的位置。因此，它似乎被舍入到0.08以显示值。因此，问题仍然存在--考虑到这些信息，是否有方法显示0.09的正确值？

Answer 1

很好的斑点！也许您应该为开发人员发布一个问题。同时，您可以做的是子类Slider类，并使用Java的DecimalFormat类修复标签：

import java.text.DecimalFormat;
import controlP5.*;

ControlP5 gui;

void setup(){
  size(640,480);
  gui = new ControlP5(this);
  CustomSlider slider = new CustomSlider(gui,"Tolerance");

  slider.setPosition(40, height-60).setSize(400, 20).setRange(0.00, 0.10).setValue(0.05);
  slider.setFont(createFont("Verdana",12));
  slider.setNumberOfTickMarks(11).setSliderMode(Slider.FLEXIBLE);
  slider.getValueLabel().align(ControlP5.RIGHT, ControlP5.TOP_OUTSIDE).setPaddingX(0);
  slider.setCaptionLabel("Comparison Tolerance");
  slider.getCaptionLabel().align(ControlP5.LEFT, ControlP5.TOP_OUTSIDE).setPaddingX(0);
}
void draw(){
  background(0);
}

//subclass slider
public class CustomSlider extends Slider{

  //decimal format reference
  DecimalFormat df;

  //constructor
  public CustomSlider( ControlP5 cp5 , String name ) {
    super(cp5,name);
    //setup decimal format proof of concept - hardcoded fractional digits for now (this can be nicer)
    df = new DecimalFormat();
    df.setMaximumFractionDigits(2);
  }

  @Override public Slider setValue( float theValue ) {
    super.setValue(theValue);
    //this can be improved, follow the CP5 component lifecycle to determine when an instance initialised in the constructor is ready
    if(df != null){
      _myValueLabel.set( df.format(getValue( )));
    }else{
      _myValueLabel.set( getValue( ) +"" );
    }
    return this;
  }

} 

​

​