F#，循环控制，直到n-2

Question

我目前正在学习函数式编程和F#，我想做一个循环控制直到n-2。例如：

Given a list of doubles, find the pairwise average,
e.g. pairwiseAverage [1.0; 2.0; 3.0; 4.0; 5.0] will give [1.5; 2.5; 3.5; 4.5]

在做了一些实验和搜索之后，我有几种方法可以做到：

方法1：

let pairwiseAverage (data: List<double>) = 
        [for j in 0 .. data.Length-2 do  
            yield (data.[j]+data.[j+1])/2.0]

方法2：

let pairwiseAverage (data: List<double>) =
        let averageWithNone acc next =
            match acc with
            | (_,None)           -> ([],Some(next))
            | (result,Some prev) -> ((prev+next)/2.0)::result,Some(next))

        let resultTuple = List.fold averageWithNone ([],None) data

        match resultTuple with
        | (x,_) -> List.rev x

方法3：

let pairwiseAverage (data: List<double>) =
        // Get elements from 1 .. n-1
        let after = List.tail data

        // Get elements from 0 .. n-2
        let before = 
            data    |> List.rev 
                    |> List.tail
                    |> List.rev

        List.map2 (fun x y -> (x+y)/2.0) before after

我只想知道是否有其他方法来处理这个问题。谢谢。

Answer 1

仅使用内置：

list |> Seq.windowed 2 |> Seq.map Array.average

Seq.windowed n为您提供n个元素的滑动窗口。

Answer 2

另一种简单的方法是使用Seq.pairwise

就像这样

list |> Seq.pairwise |> Seq.map (fun (a,b) -> (a+b)/2.0)

Answer 3

以上建议的方法适用于短窗口，如问题中的方法。对于长度大于2的窗户，不能成对使用。hlo的答案概括为更宽的窗口，如果窗口长度不太大，这是一种干净而快速的方法。对于非常宽的窗口，下面的代码运行得更快，因为它只添加一个数字，并从前一个窗口的值中减去另一个数字。注意，Seq.map2 (和Seq.map)自动处理不同长度的序列。

let movingAverage (n: int) (xs: float List) =
    let init = xs |> (Seq.take n) |> Seq.sum
    let additions = Seq.map2 (fun x y -> x - y) (Seq.skip n xs) xs
    Seq.fold (fun m x -> ((List.head m) + x)::m) [init] additions
    |> List.rev
    |> List.map (fun (x: float) -> x/(float n))
xs = [1.0..1000000.0]
movingAverage 1000 xs
// Real: 00:00:00.265, CPU: 00:00:00.265, GC gen0: 10, gen1: 10, gen2: 0

作为比较，上面的函数执行上面的计算比加窗的等价物快60倍：

let windowedAverage (n: int) (xs: float List) =
    xs 
    |> Seq.windowed n 
    |> Seq.map Array.average
    |> Seq.toList
windowedAverage 1000 xs
// Real: 00:00:15.634, CPU: 00:00:15.500, GC gen0: 74, gen1: 74, gen2: 71

我试图使用List.rev消除foldBack，但没有成功。