scons uninstall运行Substfile

Question

我已经创建了用于安装systemd用户服务的SConstruct，但是当我尝试使用scons uninstall时，会创建临时服务文件，这是不应该发生的。

import os

PATH_WD = os.path.abspath(os.curdir)

env = Environment(
    SUBSTFILESUFFIX = '.service',
    SUBST_DICT      = { '{{PATH_ROOT}}' : os.path.dirname(PATH_WD) },
    ENV             = {
        'DBUS_SESSION_BUS_ADDRESS' : os.environ['DBUS_SESSION_BUS_ADDRESS'],
        'XDG_RUNTIME_DIR'          : os.environ['XDG_RUNTIME_DIR']
    }
)

INSTALLED = env.Install(
    target = os.path.expanduser('~/.config/systemd/user/'),
    source = [
        env.Substfile('service1'),
        env.Substfile('service2'),
    ]
)
env.AddPostAction(INSTALLED, env.Action('systemctl --user daemon-reload'))

Alias('install', INSTALLED)

NoClean(INSTALLED)

Command('uninstall', INSTALLED, Delete(INSTALLED))

Default('install')

Answer 1

第二次尝试..

这里有一个很小的例子，它应该对你有效。

env=Environment()

prog=env.Program('main.c')
Default(prog)

installed_prog = env.Install('install_dir', prog)
Alias('install', installed_prog)
NoClean(installed_prog)

# You don't have to specify targets to Alias.. so it won't 
# try to build those before executing the Action 
Alias('uninstall', action=Delete(installed_prog))
AlwaysBuild('uninstall')

Answer 2

SCons构建器调用是节点之间关系的声明。通过调用Command构建器，您已经将目标"uninstall"与源INSTALLED关联起来。因此，为了“构建”这个目标，您需要源，而源是通过调用Install构建器返回的节点列表。因此，Install必须在uninstall发生之前发生。你有什么理由不想在这里使用SCons的干净功能吗？要查看这一点，请尝试：scons --tree=all,linedraw -n uninstall