CertUtil -hashfile输出到文件和错误处理

Question

我需要从同一个批处理文件中生成的文件列表中生成带有hashfile标记的文件。下面是我到目前为止掌握的代码：

@echo off
setlocal enabledelayedexpansion

:: Set the variables for this script.
set testfolder=c:\test\test folder
set listfile=c:\test\output\file list.txt
set hashfile=c:\test\output\hashes.txt

:: Delete any of the files that were created the last time this script was ran.
del "%hashfile%"
del "%listfile%"
cls

:: Generate a file with a list of all of the files (with path) in designated folder and subdirectories.
:: Directory and subdirectory names are not included in the list. Only files.
dir /s /b /a-d "%testfolder%" > "%listfile%"

:: Assign each line of the file above to its own variable.
set counter=1
for /f "usebackq delims=" %%x in ("%listfile%") do (
  set "line_!counter!=%%x"
  set /a counter+=1
)

:: Count the number of lines in the above file to use as a reference point.
set /a numlines=counter - 1

:: Generate an MD5 hash for each variable and write it to a file with a blank space between each.
for /l %%x in (1,1,%numlines%) do (
  certutil -hashfile "!line_%%x!" MD5 >> "%hashfile%"
  echo( >> "%hashfile%"
)
eof

对于我生成散列文件的大多数文件，我得到如下内容：

MD5 hash of file c:\test\test folder\Citrix 2.bmp:
31 34 d6 04 cd b0 4b ef a7 63 c3 e9 ae a8 3d 01
CertUtil: -hashfile command completed successfully.

但有时我会犯这样的错误：

CertUtil: -hashfile command FAILED: 0x800703ee (WIN32: 1006)
CertUtil: The volume for a file has been externally altered so that the opened file is no longer valid.

1. 为什么某些文件会出现此错误？
2. 我如何删除以CertUtil开头的任何行:因此我没有不必要的行，或者是否有一种方法只将CertUtil命令的前2行写入文件。
3. 在%hashfile%以其最终形式出现之后，我希望运行certutil -hashfile "%hashfile% MD5并将哈希代码赋值给一个变量。它的语法是什么？

Answer 1

稍作修改的代码片段显示，0x800703ee (WIN32: 1006 ERROR_FILE_INVALID)错误消息仅用于零长度文件 (cf )。rem注释)。

:: Generate an MD5 hash for each variable and write it to a file with a blank line...
>"%hashfile%" (
  for /l %%x in (1,1,%numlines%) do (

        rem debugging: show file length for each file
    for %%G in ("!line_%%x!") do echo(%%~zG "%%~G"

        rem operational: skip certutil for zero length files (requires elaboration)   
    certutil -hashfile "!line_%%x!" MD5
    echo(
  )
)

有关%%~zG和"%%~G"的解释，请参见%%~zG。

Answer 2

在您的批处理中，使用find /v /N完成计数步骤更简单。

for /f "tokens=3 delims=: " %%A in (
  'find /V /N /C "" %listfile%'
) Do set NumLines=%%A

但是，由于每次运行批处理时都会重新创建列表和散列文件，所以根本不需要中间步骤。

这个堆叠的--如果-- for --将在一次运行中完成：

@echo off
setlocal enabledelayedexpansion

:: Set the variables for this script.
set testfolder=c:\test\test folder
set hashfile=c:\test\output\md5-hashes.csv

>%hashfile% (
  echo "File","MD5-hash"
  For /f "delims=" %%A in (
    'dir /s /b /a-d "%testfolder%"'
  ) Do If %%~sA Gtr 0 For /f "delims=" %%B in (
    'certutil -hashfile %%A MD5 ^|findstr /i ^[0-9a-f][0-9a-f].[0-9a-f][0-9a-f].[0-9a-f][0-9a-f]'
  ) Do Echo:"%%~A","%%~B"
)

这个部分输出碰巧引用了一个可能更适合此任务的工具:-)

> type md5-hashes.csv
"File","MD5-hash"
"c:\test\md5\hashdeep.exe","23 03 ea 53 52 03 c7 93 05 49 0d 6c 20 be 84 54"
"c:\test\md5\hashdeep64.exe","66 5c cc 57 a8 4c 56 39 c4 e5 15 16 86 cc 04 32"
"c:\test\md5\md5deep.exe","23 03 ea 53 52 03 c7 93 05 49 0d 6c 20 be 84 54"
"c:\test\md5\md5deep64.exe","66 5c cc 57 a8 4c 56 39 c4 e5 15 16 86 cc 04 32"