模式匹配HTTpoison响应

Question

我们有什么方法可以与httpoison的错误响应匹配吗？我在做这件事

case HTTPoison.get!(url, [], []) do
  %HTTPoison.Error{reason: reason} ->
    IO.inspect "Media: #{reason}!"
    :timer.sleep(:timer.seconds(3))
    do_loop(starting, ending, interval, camera_exid)
  response ->
    upload(response.status_code, response.body, starting, camera_exid)
    do_loop(starting + interval, ending, interval, camera_exid)
end

但是它没有捕捉到timeout，给了我错误

** (HTTPoison.Error) :timeout
    (httpoison) lib/httpoison.ex:66: HTTPoison.request!/5
    (extractor) lib/snapshot/snap_extractor.ex:67: Extractor.SnapExtractor.do_loop/4
       (elixir) lib/enum.ex:651: Enum."-each/2-lists^foreach/1-0-"/2
       (elixir) lib/enum.ex:651: Enum.each/2

我觉得我做错了..。有什么建议吗？

Answer 1

HTTPoison.get!将raise异常，而不是返回异常，因此需要使用try ... rescue ...

try do
  response = HTTPoison.get!(url, [], [])
  upload(response.status_code, response.body, starting, camera_exid)
  do_loop(starting + interval, ending, interval, camera_exid)
rescue
  %HTTPoison.Error{reason: reason} ->
    IO.inspect "Media: #{reason}!"
    :timer.sleep(:timer.seconds(3))
    do_loop(starting, ending, interval, camera_exid)
end

但是，这并不是很好的代码，因为HTTPoison还有get，它返回{:ok, response}或{:error, error}，您可以如下所示：

case HTTPoison.get(url, [], []) do
  {:ok, response} ->
    upload(response.status_code, response.body, starting, camera_exid)
    do_loop(starting + interval, ending, interval, camera_exid)
  {:error, %HTTPoison.Error{reason: reason}} ->
    IO.inspect "Media: #{reason}!"
    :timer.sleep(:timer.seconds(3))
    do_loop(starting, ending, interval, camera_exid)
end