将非结构化xml转换为结构化

Question

我有一个非结构化XML，它必须转换为结构化XML。我是从apache解析并由Parscit转换为xml的科学pdf文件中获得这个结果的。xml如下所示：

输入

<algorithm>
    <sectionHeader> Section1 </sectionHeader>
    <BodyText>Text goes here</BodyText>
    <sectionHeader> Section2 </sectionHeader>
    <BodyText>Text goes here</BodyText>
    <subsectionHeader>Subsection</subsectionHeader>
    <BodyText>Text goes here</BodyText>
    <sectionHeader> Section1 </sectionHeader>
    <BodyText>Text goes here</BodyText>
</algorithm>

输出

<algorithm>
    <sectionHeader> 
        <Text> Section1 </Text>
        <BodyText>Text goes here</BodyText>
    </sectionHeader>
    <sectionHeader> 
       <Text> Section2 </Text>
       <BodyText>Text goes here</BodyText>
    <subsectionHeader>
        <Text>Subsection</Text>
        <BodyText>Text goes here</BodyText>
    </subsectionHeader>
</sectionHeader>
<sectionHeader> 
    <text>Section3 </Text>
    <BodyText>Text goes here</BodyText>
</sectionHeader>
</algorithm>

我可以使用java中的和xpath来完成这个任务。但它会影响性能，因为我可能需要处理数百万份文档。那么，xslt是一个更好的方法吗？

Answer 1

你可以这样做：

XSLT2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:template match="/algorithm">
    <xsl:copy>
        <xsl:for-each-group select="*" group-starting-with="sectionHeader">
            <sectionHeader> 
                <Text>
                    <xsl:value-of select="." />
                </Text>
                <xsl:for-each-group select="current-group()" group-starting-with="subsectionHeader">
                    <xsl:choose>
                        <xsl:when test="self::subsectionHeader">
                            <subsectionHeader> 
                                <Text>
                                    <xsl:value-of select="." />
                                </Text>
                                <xsl:copy-of select="current-group()[not(self::subsectionHeader)]"/>
                            </subsectionHeader> 
                        </xsl:when>
                        <xsl:otherwise>
                            <xsl:copy-of select="current-group()[not(self::sectionHeader)]"/>
                        </xsl:otherwise>
                    </xsl:choose>
                </xsl:for-each-group>
            </sectionHeader>
        </xsl:for-each-group>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>