SGPLOT -使用Y轴缩放间隔

Question

我在数据集中的值为数十亿，当我绘制数据时，Y轴显示的是2.0E7、2.0E8等中的间隔，而不是实际值。我想把这个比例尺放在传说中的“百万”里，而不是以指数的比例显示出来。怎么做？

proc sgplot data=t_analytics ;
series x=year y=CC / markers datalabel;
series x=year y=DC / markers datalabel y2axis;
series x=year y=NC / markers datalabel y2axis;
yaxis interval=auto grid logbase=10 ;
xaxis display=(nolabel) ;
run;

CC，DC，NC值以百万计。

提前感谢

Answer 1

在绘制和调整轴标签之前除以1e6。

data to_plot;
set t_analytics;
CC = CC/1e6;
DC = DC/1e6;
NC = NC/1e6;
run;

proc sgplot data=to_plot;
series x=year y=CC / markers datalabel;
series x=year y=DC / markers datalabel y2axis;
series x=year y=NC / markers datalabel y2axis;
yaxis interval=auto grid logbase=10 label="in Millions" logstyle=logexpand;
xaxis display=(nolabel) ;
run;

编辑:添加logstyle=logexpand以确保值被打印，而不是指数。应该是默认的。

Answer 2

你也可以把它写成一种格式。图片格式非常擅长乘法。

data test;
  do year=1995 to 2015;
    cc = (year-1994)*1000000;
    output;
  end;
run;

proc format;
  picture millionsF
    0-high = '00' (mult=0.000001);
quit;


proc sgplot data=test;
series x=year y=CC / markers datalabel;
format CC millionsf.;
xaxis display=(nolabel) ;
yaxis interval=auto grid logbase=10 label='In Millions';
run;

当然，如果您愿意的话，可以将in millions放在图片格式中，或者仅仅放在轴标签中。