gnuplot:在多绘图模式下绘制单个调色板

Question

我想就以下问题寻求一些帮助：

以下代码在同一页上生成3幅图(3行，1列)：

set terminal postscript color
set output "test.ps"
file="test.dat"

set palette rgb 33,13,10  
set cblabel "[km]"
set cbtics 2.5, 5, 20 format "%.0f"

set lmargin at screen 0.08
set rmargin at screen 0.88
# BUILD FROM BOTTOM TO TOP #
TOP=0.92  #
DY = 0.27 # DIMENSION OF Y

set multiplot
set grid
set offset 0, 0, graph 0.05, graph 0.05 

#unset colorbox
# BOTTOM GRAPH #
set xlabel "Second of the Week [s]"
set ylabel "Up [m]" offset 1.5
set ytics -0.7, 0.2, 0.4
set yrange[-0.75:0.35]
set tmargin at screen TOP-2*DY
set bmargin at screen TOP-3*DY
plot file u 1:12:3 notitle palette 
# MIDDLE GRAPH #
set xtics format ''
unset xlabel 
set ytics -0.3, 0.2, 0.8
set yrange[-0.35:0.75]
set ylabel "North [m]"
set tmargin at screen TOP-DY
set bmargin at screen TOP-2*DY
plot file u 1:11:3 notitle palette
# TOP GRAPH #
set title "test"
set ylabel "East [m]"
set ytics -0.7, 0.2, 0.4
set yrange[-0.9:0.25]
set tmargin at screen TOP
set bmargin at screen TOP-DY
plot file u 1:10:3 notitle palette

unset multiplot

上面的代码产生了以下情节：

​

​

在地块中，数据是根据离原点的距离来显示的。距离是彩色编码的，使用的调色板被绘制在每个图的右边。

我的问题是：-我如何获得相同的图形，但与单一的垂直调色板在右上的3个图元？我想要一个调色板从第一个图(东方)的顶部显示到第三个图(向上)的底部。这将允许我扩大调色板以及将导致一个更干净的情节。

任何帮助都是非常感谢的。

Answer 1

第一次使用

set colorbox user origin screen 0, screen 0.05 size screen XX, screen YY

在这里，您需要设置XX和YY，以适应所需的色盒宽度和高度的三个情节。

那么对于第二个情节，只需设置

unset colorbox