复制和粘贴错误：“1004”

Question

我正在使用VBA来帮助管理一组数据。我将有50个月的每月数据，我希望根据一个单元格中的第一个单词将其分类为不同的表格。以下是我迄今所做的工作；

我用两个工作表创建了一个工作簿，

1. Sheet1(员工库存)
2. Sheet2(PB)

我的代码被编写并保存在这个工作簿中。

Sub myCode()
    Dim OldString As String
    Dim NewString As String
    Set i = Sheets("Employee Inventory")
    Set PB = Sheets("PB")
    Dim counterPB
    counterPB = 2
    Dim d
    Dim j
    d = 1
    j = 2
    Do Until IsEmpty(i.Range("D" & j))
        OldString = i.Range("D" & j)
        NewString = Left(OldString, 2)
        If NewString = "PB" Then
            i.Rows(j).EntireRow.Copy
            PB.Range("A" & counterPB).Select
            PB.Paste
            counterPB = counterPB + 1
        End If
        j = j + 1
    Loop
End Sub

为代码道歉，因为它看起来很奇怪。这段代码查看Sheet1并扫描列"D“，并查找以"PB”开头的第一个单词。一旦找到它，它将复制并粘贴整个行到另一个名为Sheet2(PB)的工作表中。

当我在窗口中，打开带有Sheet1(员工库存)选项卡的Excel电子表格时，当我单击Run时，会得到以下错误:运行时错误'1004'：应用程序定义的或对象定义的错误。当我点击"PB“选项卡时，没有任何东西被复制和粘贴在那里。

但是，当我单击PB选项卡，然后单击Run时，代码将执行，包含第一个单词"PB“的行将被复制并粘贴到"PB”选项卡中。

我的问题是，为什么它只在打开Sheet2时才起作用，而在打开Sheet1时不起作用？

Answer 1

当使用range.select时，必须选择它的父工作表，因此我们可以使用PB.Activate，也可以根本不使用.select。

试着替换这个：

i.Rows(j).EntireRow.Copy
PB.Range("A" & counterPB).Select
PB.Paste

用这一行：

i.Rows(j).Copy PB.Rows(counterPB)

Answer 2

为什么不直接在代码的开头选择第二个工作表呢？

尝试以下几点

ActiveWorkbook.Sheets("Sheet2").Activate

如果在选择此工作表时它确实有效，那么它应该与此一起工作。