继续我的另一个问题:如何将内存流从应用程序传递/从DLL中检索?
我使用作为输入/输出编写了DLL。DLL使用IXMLDocument (我最初认为它与下面的问题有关)对它进行了测试,它在主UI中运行良好。当我从工作线程调用DLL时,问题就开始了。
DLL:
library MyDLL;
uses
Windows,
Variants,
SysUtils,
Classes,
AxCtrls,
ActiveX,
XMLDoc,
XMLIntf;
{$R *.res}
procedure Debug(V: Variant);
begin
OutputDebugString(PChar(VarToStr(V)));
end;
procedure DoProcess(InStream, OutStream: TStream);
var
Doc: IXMLDocument;
begin
InStream.Position := 0;
Doc := TXMLDocument.Create(nil);
Doc.LoadFromStream(InStream);
// plans to do some real work...
OutStream.Position := 0;
Debug('MyDLL DoProcess OK');
end;
function Process(AInStream, AOutStream: IStream): Integer; stdcall;
var
InStream, OutStream: TStream;
begin
try
InStream := TOleStream.Create(AInStream);
try
OutStream := TOleStream.Create(AOutStream);
try
DoProcess(InStream, OutStream);
Result := 0;
finally
OutStream.Free;
end;
finally
InStream.Free;
end;
except
on E: Exception do
begin
Result := -1;
Debug('MyDLL Error: ' + E.Message);
end;
end;
end;
exports
Process;
begin
end.我的来电者申请:
implementation
uses
ActiveX,ComObj;
{$R *.dfm}
procedure Debug(V: Variant);
begin
OutputDebugString(PChar(VarToStr(V)));
end;
const
MyDLL = 'MyDLL.dll';
{$DEFINE STATIC_DLL}
{$IFDEF STATIC_DLL}
function Process(AInStream, AOutStream: IStream): Integer; stdcall; external MyDLL;
{$ENDIF}
type
// Dynamic
TDLLProcessProc = function(AInStream, AOutStream: IStream): Integer; stdcall;
function DLLProcess(AInStream, AOutStream: TStream): Integer;
var
InStream, OutStream: IStream;
Module: HMODULE;
DLLProc: TDLLProcessProc;
begin
InStream := TStreamAdapter.Create(AInStream, soReference);
OutStream := TStreamAdapter.Create(AOutStream, soReference);
{$IFDEF STATIC_DLL}
Result := Process(InStream, OutStream); // Static
Exit;
{$ENDIF}
// Dynamic load DLL ...
Module := LoadLibrary(MyDLL);
if Module = 0 then RaiseLastOSError;
try
DLLProc := GetProcAddress(Module, 'Process');
if @DLLProc = nil then RaiseLastOSError;
Result := DLLProc(InStream, OutStream);
finally
FreeLibrary(Module);
end;
end;
type
TDLLThread = class(TThread)
private
FFileName: string;
public
constructor Create(CreateSuspended: Boolean; AFileName: string);
procedure Execute(); override;
end;
constructor TDLLThread.Create(CreateSuspended: Boolean; AFileName: string);
begin
FreeOnTerminate := True;
FFileName := AFileName;
inherited Create(CreateSuspended);
end;
procedure TDLLThread.Execute;
var
InStream, OutStream: TMemoryStream;
RetValue: Integer;
begin
try
//CoInitializeEx(nil, COINIT_APARTMENTTHREADED);
CoInitialize(nil);
try
InStream := TMemoryStream.Create;
try
InStream.LoadFromFile(FFileName);
OutStream := TMemoryStream.Create;
try
RetValue := DLLProcess(InStream, OutStream);
Sleep(0);
Debug('TDLLThread Result=> ' + IntToStr(RetValue));
if RetValue = 0 then
begin
Debug('TDLLThread OK');
end;
finally
OutStream.Free;
end;
finally
InStream.Free;
end;
finally
CoUninitialize;
end;
except
on E: Exception do
begin
Debug('TDLLThread Error: ' + E.Message);
end;
end;
end;
procedure TForm1.Button1Click(Sender: TObject); // Test
var
I: Integer;
begin
for I := 1 to 5 do
TDLLThread.Create(False, '1.xml');
end;在运行一些测试时,我有时会得到访问冲突,即使是异常块也无法捕捉这些冲突。程序简单地使用Runtime error 216 at xxxxxxx或Invalid pointer operation崩溃。
我尝试过静态和动态DLL链接(,可能是,动态链接在LoadLibrary/FreeLibrary中有竞争条件)。
首先,我认为IXMLDocument是主要问题:
Doc := TXMLDocument.Create(nil);
Doc.LoadFromStream(InStream);这有时是随机失败的,没有明显的理由:
在文档的顶层无效。
或者:
名称以无效字符启动。
我想也许它使用了一些共享的资源。但是即使忽略了这些行,也会导致AVs的出现!
所以DLL实际上没什么特别的。我也看不出有什么特别的东西可以感染DLLMain。
我不知道发生了什么..。有人能建议如何处理这种情况吗?(有人能复制这种行为吗?)
编辑:我只是想添加一个相关的问题(使用类似的IsMultiThread解决方案):Delphi线程安全
还有一些关于IsMultiThread:IsMultiThread变量的建议
发布于 2015-12-18 18:18:58
Delphi中的内存管理器对单线程的使用进行了优化。默认情况下,这些都是启用的。如果您的代码是多线程的,则需要禁用此优化。为此,请将IsMultiThread设置为True。
在创建Delphi线程的模块中,框架在创建线程时将IsMultiThread设置为True。在您的程序中,线程是由主机创建的,因此库中没有任何东西将IsMultiThread设置为True。因此,您必须在DLL中显式地执行此操作。在库.dpr文件的主要部分中,可以这样写:
begin
IsMultiThread := True;
end.https://stackoverflow.com/questions/34355162
复制相似问题