将一维阵列传递给三维阵列

Question

我在Fortran中使用了一个API，它提供了一个编写数据的例程。让我们假设它的名字是api_write_data。这个例程需要一个数组作为参数，它可以是维度1、2或3。

我想编写一个子例程，它作为这个API例程的包装器。因此，我有必要编写一个例程，它可以处理1D、2D或3D数组，并能够将它们正确地传递给API例程。我怎么能这么做？我可以这么做吗？

我的方法是这样的，但不起作用：

subroutine write_data(array)
implicit none
integer, dimension(:,:,:), intent(in):: array

call api_write_data(array)

end subroutine write_data

但是，当我用一个一维数组调用这个例程时，我得到了已知的错误：

Error: Rank mismatch in argument 'array' at (1) (rank-3 and rank-1)

在Fortran有办法做那种事吗？对我来说，有必要将数组作为一个一维、二维或三维数组传递给write_data例程。但是，我可以将数组作为一维数组传递给api_write_data。

你知道我该怎么做吗？

Answer 1

reshape函数的替代方法可能是有一个指向多维数组的一维指针：

p(1:size(c)) => c(:,:,:)

您可以将指针作为一维数组传递，而无需复制.实际上，它应该和传递数组本身一样快。当然，您需要一些方法来告诉子例程数组的形状有：

module test_mod
contains
  subroutine print_arr( arr, dimX, dimY, dimZ )
    integer,intent(in)  :: arr(:)
    integer,intent(in)  :: dimX, dimY, dimZ

    if ( dimZ == 0 ) then
      if ( dimY == 0 ) then
        ! 1D
        print *, "1D array provided"
        print *, "a(4) =", arr(4)
      else
        ! 2D
        print *, "2D array provided"
        print *, "a(1,2) =", arr((2-1)*dimX+1)
      endif
    else
      ! 3D
      print *, "3D array provided"
      print *, "a(1,2,1) =", arr( ((1-1)*dimY + (2-1))*dimX+1)
    endif
  end subroutine
end module

program test
use test_mod
  integer :: i
  integer, target   :: a(8)
  integer, target   :: b(4,2) 
  integer, target   :: c(2,2,2)
  integer, pointer  :: p(:)

  a = [ (i,i=1,8) ]
  b = reshape( a, [4,2] )
  c = reshape( a, [2,2,2] )

  p(1:size(a)) => a(:)
  call print_arr( p, 8, 0, 0 )

  p(1:size(b)) => b(:,:)
  call print_arr( p, 4, 2, 0 )

  p(1:size(c)) => c(:,:,:)
  call print_arr( p, 2, 2, 2 )
end program

这也正好相反..。您可以将一维数组映射到3D指针：

integer, pointer  :: p2(:,:,:)
!...
p2(1:4,1:2,1:1) => a

Answer 2

您可以使用Fortran接口定义几个例程的版本：

interface write_data
  module procedure write_data_1d
  module procedure write_data_2d
  module procedure write_data_3d
end interface write_data

然后，这些过程可以处理不同类型的输入。然后，在这些过程中，您可以使用RESHAPE函数将输入转换成一个方便的形状，这样所有这三个步骤都可以调用一个公共子例程来实现您所做的任何事情的逻辑。