SAS:强制PROC GCHART显示空列

Question

我用PROC GCHART创建了一个图表。假设数据如下所示：

Month    Volume
Jan      2
Feb      4
May      19
Sep      7

当我用GCHART使用月份和卷创建图形时，我得到了四个条。不过，我希望看到整个一年(剩下的几个月都是空栏)。我试着用：

axis order=('Jan','Feb',...,'Nov','Dec');

但是，我只得到了四列而不是十二列。我能做什么?

谢谢。

Answer 1

您需要创建一个包含没有数据的月份的数据集。然后，在AXIS语句中使用该数据集，强制所有月份都出现在GCHART中。参见下面的示例代码。希望这能有所帮助。

data have;
    infile cards;
    input Month $  Volume;
    cards;
Jan      2
Feb      4
May      19
Sep      7
;
run;


*** CREATE A DATASET WITH ALL 12 MONTHS ***;
data allmon;
    infile cards;
    input Month $ @@;
    cards;
Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec
;
run;

*** USE PROC SQL TO MERGE BOTH DATASETS WITHOUT HAVING TO SORT FIRST ***;
*** USE THIS DATASET WITH GCHART ***;
proc sql;
    create table want as
    select *
    from allmon left join have
    on (allmon.month = have.month)
;
run;

proc print data=want;
run;


axis1 order=('Jan' 'Feb'  'Mar' 'Apr' 'May' 'Jun' 'Jul' 'Aug' 'Sep' 'Oct' 'Nov' 'Dec');

proc gchart data=want;
    vbar month / sumvar=volume maxis=axis1;
run;