JENA Triplestore中的替换域

Question

我想替换存储在基于耶拿的三重存储中的所有主题的服务器。

我试过了，但是服务器没有被替换.

DELETE { ?s ?p ?o }
INSERT { ?s1 ?p ?o }
WHERE { 
    { SELECT (uri(concat('http://localhost:8080/', SUBSTR(str(?s),22))) AS ?s1) 
        { 
          ?s ?p ?o . 
          FILTER regex(str(?s), '^https://somedomain.org/')
        }
     }
}

当我只运行以下查询时

SELECT (uri(concat('http://localhost:8080/', SUBSTR(str(?s),22)) ) AS ?s1) ?s 
{ 
  ?s ?p ?o . 
  FILTER regex(str(?s), '^https://somedomain.org/')
}

‘s’和‘s1’确实有正确的值。

似乎删除/插入块中没有‘s’和‘s1’。我的更新查询有什么问题？

Answer 1

您的问题是在更新中使用子查询，并且只从子查询中生成?s1。

这意味着?s、?p和?o在子查询之外是不可见的。因此，当DELETE和INSERT模板试图构建三元组以删除和插入它们构建的所有三元组时，它们构建的所有三元组都是无效的(因为并非所有变量都是可见的)，因此没有任何变化。

要解决这个问题，您应该投影所有相关变量：

DELETE { ?s ?p ?o }
INSERT { ?s1 ?p ?o }
WHERE 
{ 
  {
    SELECT ?s ?p ?o (uri(concat('http://localhost:8080/', SUBSTR(str(?s),22))) AS ?s1) 
    { 
      ?s ?p ?o . 
      FILTER regex(str(?s), '^https://somedomain.org/')
    }
  }
}

或者根据评论中的Joshua Taylor's建议。这实际上更好，因为它简化了整个查询：

DELETE { ?s ?p ?o }
INSERT { ?s1 ?p ?o }
WHERE 
{ 
  ?s ?p ?o . 
  FILTER regex(str(?s), '^https://somedomain.org/')
  BIND(uri(concat('http://localhost:8080/', SUBSTR(str(?s),22))) AS ?s1)
}