将百分比添加到proc表报告中

Question

我有如下所示的proc表格代码：

  proc tabulate data=want;
class TERM CAMPUS GENDER ;
  var count ;
 table  GENDER ALL, (CAMPUS all)*TERM*(count='#Enrl '*f=best8.*sum=' ' count=''*colpctsum='% Tot Enrl ' ) / rts=20;
run;

我的结果如下

                               campus
                             East Campus
                               Term
           Spring 2014               Spring 2015             Dfference
        #Enrl     %Tot_Enrl         #Enrl   %ToT_Enrl      #Enrl   %Tot_Enrl
Gender   
Female   8462      52.86             8429    52.36          -33       -37.08
Male     7478      46.71             7608    47.26          130       146.07
None     68        0.42              60      0.37            -8        -8.89
All      16008      100.00           16907    100.00        89          100

我需要在'%Tot_Enrl‘变量中添加%签名。另外，我可以删除校园和学期名称吗？我有“校园”和“东校区”的头衔。所以我需要删除“校园”和“学期”。这有可能吗？

Answer 1

你需要更多的=' '来摆脱校园和学期。要获得百分比签名，您需要一个格式；SAS向你展示了这里。

data want;
  format term $15. campus $15.;
  input term $ & campus $ & gender $ count;
  datalines;
Spring 2014  East Campus  Female 8462
Spring 2014  East Campus  Male 7478
Spring 2014  East Campus  None 68
Spring 2015  East Campus  Female 8429
Spring 2015  East Campus  Male 7608
Spring 2015  East Campus  None 60
Difference  East Campus  Female -33
Difference  East Campus  Male 130
Difference  East Campus  None -8
;;;;
run;



proc format;                           
   picture mypct(round) low-high='000,009.90%' (mult=100);   
run; 


proc tabulate data=want;
  class TERM CAMPUS GENDER ;
  var count ;
  table  GENDER ALL, (CAMPUS=' ' all)*TERM=' '*(count='#Enrl '*f=best8.*sum=' ' count=''*colpctsum='% Tot Enrl '*f=mypct. ) / rts=20;
run;

排序结果是错误的，我猜您有一个格式化的数字，但它能让人理解。