GLSL HSV着色器

Question

我想在我的cocos2d-x游戏中使用GLSL着色器，这将使精灵更加明亮。

这是我的着色器

#ifdef GL_ES
precision mediump float;
#endif

varying vec4 v_fragmentColor;
varying vec2 v_texCoord;

vec3 rgb2hsv(vec3 c)
{
    vec4 K = vec4(0.0, -1.0 / 3.0, 2.0 / 3.0, -1.0);
    vec4 p = mix(vec4(c.bg, K.wz), vec4(c.gb, K.xy), step(c.b, c.g));
    vec4 q = mix(vec4(p.xyw, c.r), vec4(c.r, p.yzx), step(p.x, c.r));

    float d = q.x - min(q.w, q.y);
    float e = 1.0e-10;
    return vec3(abs(q.z + (q.w - q.y) / (6.0 * d + e)), d / (q.x + e), q.x);
}

vec3 hsv2rgb(vec3 c)
{
    vec4 K = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
    vec3 p = abs(fract(c.xxx + K.xyz) * 6.0 - K.www);
    return c.z * mix(K.xxx, clamp(p - K.xxx, 0.0, 1.0), c.y);
}

void main(void)
{
    vec4 c = texture2D(CC_Texture0, v_texCoord);
    vec4 final = c;

    vec3 rgb = vec3(c.r, c.g, c.b);
    vec3 hsv = rgb2hsv(rgb);
    hsv.z = min(hsv.z + 1.0, 255.0); //HERE IS HOW MUCH BRIGHTNESS SHOULD BE ADDED
    vec3 nrgb = hsv2rgb(hsv);

    final.r = nrgb.x;
    final.g = nrgb.y;
    final.b = nrgb.z;

    gl_FragColor = final;
}

从这里取rgb到hsv，反之亦然：http://lolengine.net/blog/2013/07/27/rgb-to-hsv-in-glsl

下面是添加了"0“的图像(hsv.z = min(hsv.z + 0.0,255.0);)：

​

​

什么都没变，这是意料之中的。它使确信的转换工作。

下面是一个带有"1“加法的图像(hsv.z = min(hsv.z + 1.0,255.0);)：

​

​

所以，它应该是稍微亮一点，但它看起来就像屏幕截图。例如，将"1“改为"10”将使图像变为纯白色。

我知道在某个地方是个陷阱，但我不知道出了什么问题。

Answer 1

正如@cololel32o所说，RGB和HSV值在0，1范围内。

所以你的代码应该是：

void main(void)
{
   vec4 c = texture2D(CC_Texture0, v_texCoord);
   vec3 hsv = rgb2hsv(c.rgb);

   hsv.z = clamp(hsv.z + 0.05, 0.0, 1.0); // Add 1/20 of brightness.

   gl_FragColor = hsv2rgb(hsv);
}