虚拟静态值类型

Question

是否有可能为编译时类型安全性和功能重载创建“虚拟”值类型？

例如，greet函数总是接受字符串，但是根据产生字符串的方法，它将调用正确的变量。

我想这样做是为了简化库的API。例如，与greetByFirstName和greetByLastName不同，我只需要一个问候方法，如下所示：

import std.array;
import std.format;
import std.stdio;

string firstName(string name) {
    return name.split(" ")[0];
}

string lastName(string name) {
    return name.split(" ")[1];
}

string greet(FirstName name) {
    return "Hi %s!".format(name);
}

string greet(LastName name) {
    return "Hello Mr. %s!".format(name);
}

unittest {
    string name = "John Smith";
    assert(firstName(name) == "John");
    assert(firstName(name).greet() == "Hi John!");
    assert(lastName(name).greet() == "Hello Mr. Smith!");
}

void main() {}

Answer 1

您可以创建一个新类型，它将alias this转换为基类型，然后在更特定的类型上重载。别名--可以认为这是一种使用结构进行继承的方法，并将其隐式转换回基“接口”类型。

 // these are the new types
struct FirstName { 
    string name; 
    alias name this; // this allows implicit conversion back to string when needed
} 
struct LastName { 
    string name; 
    alias name this; 
} 
FirstName firstName(string name) {  // these return the more specific  type
    return FirstName(name.split(" ")[0]); 
} 
LastName lastName(string name) { 
    return LastName(name.split(" ")[1]); 
}  

现在，您的其余代码将根据需要工作，您仍然可以在需要时将FirstName和LastName作为字符串处理。