在elisp中多个列表的交集

Question

如何使用elisp获得多个列表的交集？我是一个新手，但我想象有一些内置的函数或一个更好的解决方案使用的减少。我把这个拼凑在一起，但看起来太复杂了。

;; get the intersection of these lists
;; result should be (3 4 5)
(setq test '((0 1 2 3 4 5) (2 3 4 5 6) (3 4 5 6 7)))

(require 'cl-lib)
(cl-remove-if-not
 (lambda (x) (cl-every
         (lambda (y) (> (length (memq x y) ) 0 ) )
         (cdr test) ) )
 (car test) )
;; ( 3 4 5)

Answer 1

有一个只使用两个操作数的cl-intersection：

(cl-intersection '(0 1 2 3 4 5) '(2 3 4 5 6))

您可以使用它来定义您自己的交集：

(defun my-intersection(l)
    (cond ((null l) nil)
          ((null (cdr l)) (car l))
          (t (cl-intersection (car l) (my-intersection (cdr l))))))

(my-intersection '((0 1 2 3 4 5) (2 3 4 5 6) (3 4 5 6 7)))

更新的

由于下面的@Tobias注释，您可以在新函数中使用cl-intersection的相同关键字参数，即(:test :test-not :key)，并将它们传播到递归中对它的所有调用。

以下是扩展版本：

(defun my-intersection(l &rest cl-keys)
    (cond ((null l) nil)
          ((null (cdr l)) (car l))
          (t (apply 'cl-intersection (car l) (apply 'my-intersection (cdr l) cl-keys) cl-keys))))

Answer 2

安装破折号第三方列表操作库(按照使用说明安装)。那么你需要：

(-reduce '-intersection '((1 2 3 4) (2 3 4 5) (3 4 5 6))) ; => (3 4)

如果需要接受可变列表数的函数，而不是单个列表列表，请使用&rest关键字将其包装在函数中，如下所示：

(defun -intersection* (&rest list-of-lists)
  (-reduce '-intersection list-of-lists))
;; (-intersection* '(1 2 3 4) '(2 3 4 5) '(3 4 5 6)) ; => (3 4)

如果这是您第一次使用-reduce，那么它就是一个“折叠”函数:它接受一个二进制函数，一个元素列表，并将它们缩减为最终结果--每次一个list元素。这个答案解释了折叠背后的概念。