如何在Clojure中向Hash-Map图添加一个新节点？

Question

我在Clojure中创建了以下数组映射。

{:node 7, :children [{:node 8, :children []} {:node 6, :children []} {:node 23, :children {}} {:node 43, :children []}]}

如何在其中添加元素，运行以下代码

(def tree (assoc-in tree [:node] 12))

给我

{:node 12, :children [{:node 8, :children []} {:node 6, :children []} {:node 10, :children {}} {:node 13, :children []} {:node 28, :children []}]}`

和奔跑

(def tree (assoc-in tree [:node :children] 12))

给我以下错误信息。如何将元素添加到数组映射的子部分中？

Exception in thread "main" java.lang.ClassCastException: java.lang.Long cannot be cast to clojure.lang.Associative,

Answer 1

让我们把树分配给t

(def t {:node 7, 
        :children [{:node 8, :children []} 
                   {:node 6, :children []} 
                   {:node 23, :children []} 
                   {:node 43, :children []}]})

若要添加新的子注释，请执行以下操作：

(defn add-child [tree node]
  (assoc-in tree 
            [:children] 
            (conj (:children tree) node)))

(add-child t :foo)
;; => {:node 7, 
;;     :children [{:node 8, :children []} 
;;                {:node 6, :children []} 
;;                {:node 23, :children []} 
;;                {:node 43, :children []} 
;;                :foo]}

当然，这不是我们想要的。

(defn make-node [value children] 
  (let [c (into [] children)] 
    {:node value 
     :children c}))

(make-node 5 nil)
;; => {:node 5, :children []}

(make-node 5 [(make-node 3 nil) (make-node 7 nil)])
;; => {:node 5, 
;;     :children [{:node 3, :children []} 
;;                {:node 7, :children []}]}

现在，建立树是make-node和add-child相结合的问题。

如果您想要处理深度层次结构，我建议使用拉链。

Answer 2

对于添加一个新节点，基本思想是通用的。不管怎么说，程序需要知道把新来的孩子放在哪里。当到达新子节点的父节点时，prog会将新的子节点追加到它。剩下的问题是如何在clojure中遍历一个图。clojure.walk模块就是为此目的而设计的。

将新节点添加到图中的一个实现如下：

(defn tree-add
  [root parent-key new-node]
  (clojure.walk/postwalk #(if (= parent-key (:node %))
                            (assoc % :children (conj (:children %) new-node))
                            %)
                         root))

测试：

user> a
{:node 7, :children [{:node 8, :children []}]}
user> (tree-add a 7 {:node 99 :children []})
{:node 7, :children [{:node 8, :children []} {:node 99, :children []}]}
user> (tree-add a 8 {:node 199 :children []})
{:node 7, :children [{:node 8, :children [{:node 199, :children []}]}]}