将Clojure中的向量映射转换为列的向量

Question

我有一个地图集合(或列表、序列或向量)，如下所示：

{ :name "Bob", :data [32 11 180] }
{ :name "Joe", :data [ 4  8  30] }
{ :name "Sue", :data [10  9  40] }

我希望创建新的向量，包含与描述数据的键关联的向量“列”中的数据，如下所示：

{ :ages [32 4 10], :shoe-sizes [11 8 9], :weights [180 30 40] }

实际上，一份简单的向量清单可能是足够的，即：

[32 4 10] [11 8 9] [180 30 40]  

如果把原始列表变成向量更好/更容易，那就好了；任何最简单的东西都行。

Answer 1

给定的

(def records
  [{:name "Bob" :data [32 11 180]}
   {:name "Joe" :data [ 4  8  30]}
   {:name "Sue" :data [10  9  40]}])

您可以执行下一个转换以获得所需的结果：

(->> records
     (map :data) ; extract :data vectors 
     ; => ([32 11 180] [4 8 30] [10 9 40])
     (apply map vector) ; transpose
     ; => ([32 4 10] [11 8 9] [180 30 40])
     (zipmap [:ages :shoe-sizes :weights])) ; make map 
     ; => {:weights [180 30 40], :shoe-sizes [11 8 9], :ages [32 4 10]}

如果没有注释，它看起来会更干净一些：

(->> records 
     (map :data)
     (apply map vector)
     (zipmap [:ages :shoe-sizes :weights]))

如果没有穿线宏，它就相当于更详细：

(let [extracted (map :data records)
      transposed (apply map vector extracted)
      result (zipmap [:ages :shoe-sizes :weights] transposed)]
  result)

Answer 2

您可以像这样使用减缩：

(def data [{ :name "Bob", :data [32 11 180] }
           { :name "Joe", :data [ 4  8  30] }
           { :name "Sue", :data [10  9  40] }])

(reduce 
  (fn [acc {[age shoe-size weight] :data}]
    (-> acc
      (update-in [:ages] conj age)
      (update-in [:shoe-sizes] conj shoe-size)
      (update-in [:weights] conj weight)))
{}
data)

返回如下内容：

{:weights (40 30 180), :shoe-sizes (9 8 11), :ages (10 4 32)}

我认为这段代码最有趣的部分是使用嵌套的析构来获取键：{[age shoe-size weight] :data}。