(gensym)总是唯一的，‘(symb#)不是--为什么？

Question

如果我编写了一个宏，它使用symb#快捷方式创建一个gensym，然后将其绑定为一个全局变量，则会一次又一次地生成完全相同的符号。但是，如果手动调用gensym，它将正确运行。非常简单的例子：

(defmacro indirection
    [name & body]
    `(do (def name# ~@body)
         (defn ~name [] name#)))

(indirection foo 3)
(foo) ; ⇒ 3
(indirection goo 5)
(goo) ; ⇒ 5
(foo) ; ⇒ 5

如果使用macroexpand，问题就很明显。

(macroexpand '(indirection foo 3))
(do (def name__2863__auto__ 3) (clojure.core/defn foo [] name__2863__auto__))
(macroexpand '(indirection foo 3))
(do (def name__2863__auto__ 3) (clojure.core/defn foo [] name__2863__auto__))

如果我用很长的方式调用gensym，这个问题就会消失：

(defmacro redirection
    [name & body]
    (let [rename (gensym)]
        `(do (def ~rename ~@body)
             (defn ~name [] ~rename))))

(redirection koo 3)
(koo) ; ⇒ 3
(redirection moo 5)
(moo) ; ⇒ 5
(koo) ; ⇒ 3

那么，为什么会有区别？我遗漏了什么？

Answer 1

使用`引用的语法实际上是一个reader macro；它后面的形式在计算之前由读取器(它将文本转换为Clojure表单)进行转换。这意味着在语法引用中以#结尾的任何符号在文本第一次读取时只被翻译成自动生成的符号一次；然后自动生成的符号将直接插入到宏定义中，并在每次调用宏时逐字显示在宏扩展中。在REPL中可以很容易地说明这一点：

user=> `(foo bar#)
(user/foo bar__2288__auto__)
user=> `(foo bar#)
(user/foo bar__2291__auto__)

带有#的自动生成符号的典型用例是在引用的let或fn表单中定义局部变量。在那里，同样的符号被重新用于多个宏调用并不重要；它只需要在每次调用中都是唯一的。例如：

(defmacro indirection
  [name body]
  `(let [name# ~body]
     (defn ~name [] name#)))