XSL for-每个具有获取动态列号的位置的

Question

这对我没用。根据XML中的节点数，我试图为我的表获得正确的额外列数。在这个例子中，我有两个“实质性”节点，但是我的XML数据可以有一个到四个，因此我的表可以有一个和四个额外的列。第一列将永远在那里。

以下是我的XML：

<stuff>
    <thing>house</thing>
    <color>red</color>
</stuff>
<stuff>
    <thing>hat</thing>
    <color>brown</color>
</stuff>

这是我的XSL：

<fo:table width="100%" table-layout="fixed">
    <fo:table-column column-width="27%" column-number="1"/>
    <xsl:for-each select="stuff">
        <xsl:if test="position()=1">
            <fo:table-column column-width="73%" column-number="2"/>
        </xsl:if>
        <xsl:if test="position()=2">
            <fo:table-column column-width="36.5%" column-number="2"/>
            <fo:table-column column-width="36.5%" column-number="3"/>
        </xsl:if>
        <xsl:if test="position()=3">
            <fo:table-column column-width="24%" column-number="2"/>
            <fo:table-column column-width="24%" column-number="3"/>
            <fo:table-column column-width="25%" column-number="4"/>
        </xsl:if>
        <xsl:if test="position()=4">
            <fo:table-column column-width="18.25%" column-number="2"/>
            <fo:table-column column-width="18.25%" column-number="3"/>
            <fo:table-column column-width="18.25%" column-number="4"/>
            <fo:table-column column-width="18.25%" column-number="5"/>
        </xsl:if>                                   
    </xsl:for-each>
    <fo:table-body>
        <fo:table-row>
            <fo:table-cell>
                <fo:block>
                    <fo:block>First Row</fo:block>
                </fo:block>
            </fo:table-cell>
            <xsl:for-each select="stuff">
                <fo:table-cell>
                    <fo:block>
                        <xsl:value-of select="thing"/>
                    </fo:block>
                </fo:table-cell>
            </xsl:for-each>
        </fo:table-row> 
        <fo:table-row>
            <fo:table-cell>
                <fo:block>
                    <fo:block>Second Row</fo:block>
                </fo:block>
            </fo:table-cell>
            <xsl:for-each select="stuff">
                <fo:table-cell>
                    <fo:block>
                        <xsl:value-of select="color"/>
                    </fo:block>
                </fo:table-cell>
            </xsl:for-each>
        </fo:table-row>         
    </fo:table-body>
</fo:table>

Answer 1

我觉得你想做这样的事：

<xsl:template match="parent-of-stuff">
    <fo:table width="100%" table-layout="fixed">
        <fo:table-column column-width="27%" column-number="1"/>
        <xsl:variable name="n" select="count(stuff)" />
        <xsl:for-each select="stuff">
            <fo:table-column column-width="{73 div $n}%" column-number="{position() + 1}"/>
        </xsl:for-each>

        <!-- the rest of the table -->

  </fo:table>  
</xsl:template>

如果3列场景的column-width="24.3333333333333%"结果不可接受，请执行以下操作：

<xsl:template match="parent-of-stuff">
    <fo:table width="100%" table-layout="fixed">
        <fo:table-column column-width="27%" column-number="1"/>
        <xsl:variable name="n" select="count(stuff)" />
        <xsl:for-each select="stuff">
            <fo:table-column column-number="{position() + 1}">
                <xsl:attribute name="column-width">
                    <xsl:choose>
                        <xsl:when test="$n=3 and position()=3">25%</xsl:when>
                        <xsl:when test="$n=3">24%</xsl:when>
                        <xsl:otherwise>
                            <xsl:value-of select="73 div $n" />
                        </xsl:otherwise>
                    </xsl:choose>
                </xsl:attribute>
            </fo:table-column>
        </xsl:for-each>

    <!-- the rest -->

  </fo:table>  
</xsl:template>