GHC.Generics示例不工作

Question

我试图让GHC.Generics中描述的一个通用二进制编码类的示例实现正常工作，但是当我试图编译它时，会出现一个错误。

import GHC.Generics

class Encode' f where
  encode' :: f p -> [Bool]

instance Encode' V1 where
  encode' x = undefined

instance Encode' U1 where
  encode' U1 = []

instance (Encode' f, Encode' g) => Encode' (f :+: g) where
  encode' (L1 x) = False : encode' x
  encode' (R1 x) = True  : encode' x

instance (Encode' f, Encode' g) => Encode' (f :*: g) where
  encode' (x :*: y) = encode' x ++ encode' y

instance (Encode c) => Encode' (K1 i c) where
  encode' (K1 x) = encode x

instance (Encode' f) => Encode' (M1 i t f) where
  encode' (M1 x) = encode' x

class Encode a where
  encode :: a -> [Bool]
  default encode :: (Generic a) => a -> [Bool]
  encode x = encode' (from x)

GHC抱怨：

Could not deduce (Encode' (Rep a)) arising from a use of ‘encode'’
from the context (Encode a)
  bound by the class declaration for ‘Encode’
  ...
or from (Generic a)
  bound by the type signature for encode :: Generic a => a -> [Bool]
  ...
In the expression: encode' (from x)
In an equation for ‘encode’: encode x = encode' (from x)

我遗漏了什么？

Answer 1

不是所有的Generic都可以由encode'编码。只有那些同时具有Generic和表示的事物，具有Encode'实例的Rep a才能被泛型encode'编码。编译器不知道(也不知道)没有Generic的Rep不被Encode'实例覆盖的东西。Generic实例的作者可以为他们的Rep使用一个甚至还不存在的类型。

您需要将请求的Encode' (Rep a)约束添加到default encode的上下文中。

default encode :: (Generic a, Encode' (Rep a)) => a -> [Bool]