首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >使用批处理文件获取目录名称和每个目录中的文件数。

问使用批处理文件获取目录名称和每个目录中的文件数。
EN

Stack Overflow用户
提问于 2015-02-28 20:20:57
回答 1查看 392关注 0票数 0

我对批处理文件和代码的使用相当陌生。我想做的是得到一个目录/子目录的列表,并得到特定文件的数量(.txt、.MP4等)。在每个目录中,然后将两者存储在一个.txt文件中。我已经知道了如何获取目录列表并存储它们:

代码语言:javascript
复制
dir /b /ad "C:\FILE" > "C:\List.txt"

现在,我如何获得每个目录中的文件数?我希望文本文件中的格式类似于:

"folder1 -5文件“

"folder2 -3文件“

文件夹名和一行中的文件数,然后是下一个文件夹。谢谢你能帮我的忙。

EN

回答 1

Stack Overflow用户

发布于 2015-03-01 21:23:39

下一个脚本可能会像预期的那样工作。使用rem注释给出的一些基本解释。

代码语言:javascript
复制
@ECHO OFF >NUL
SETLOCAL enableextensions

    rem set up initial folder
set "myFolder=C:\FILE"

    rem set up extension list (no * or ? wildcards, please)
    rem could be defined explicitly as follows
set "myExtens=bat html"
    rem or, with next  proposed usage: 28786418.bat "bat html"
set "myExtens=%~1"
    rem or, with next (current) usage: 28786418.bat bat html
set "myExtens=%*"

    rem call a subroutine to output folder name & file count 
call :filecount "%myFolder%"

    rem call that subroutine for ech subfolder (cf. /A:D /S switch)
for /F "tokens=*" %%g in ('
    DIR /B /A:D /S "%myFolder%"
  ') do call :filecount "%%~g"

ENDLOCAL
goto :eof

:filecount
    rem subroutine
    rem input: (full) path to folder
    rem output: echo "input" - file count

    rem init a file counter to zero 
set /A "numFiles=0"
    rem increment file counter by 1 for each file in folder
    rem note '2^>nul' to avoid "file not found" message if folder empty
    rem note 'set' does not require delayed variable expansion
    rem            as the 'numFiles' variable correctly increments
for /F "tokens=*" %%G in ('
    DIR /B /A:-D "%~1" 2^>nul
  ') do (
         rem treat the extension list if any
         rem ( or insert here any other logic instead ) 
      if defined myExtens (
        for %%H in (%myExtens%) do if /i ".%%~H"=="%%~xG" set /A "numFiles+=1"
      ) else (
        set /A "numFiles+=1"
      )
    )
    rem display output to console (command line window)
echo "%~1" - %numFiles%
goto :eof

要将输出存储到文本文件,可以使用(假设脚本保存为28786418.bat)

代码语言:javascript
复制
 28786418.bat>list.txt

编辑(补充):set "myFolder=d:\bat\StackOverflow"输出

代码语言:javascript
复制
==>D:\bat\StackOverflow\28786418.bat
"d:\bat\StackOverflow" - 44
"d:\bat\StackOverflow\files" - 27
"d:\bat\StackOverflow\files\backup_done" - 0
"d:\bat\StackOverflow\files\Roboto" - 0
"d:\bat\StackOverflow\files\root" - 0
"d:\bat\StackOverflow\files\Roboto\backup_done" - 0
"d:\bat\StackOverflow\files\root\Ian-ionescu" - 2
"d:\bat\StackOverflow\files\root\John-doe" - 2
"d:\bat\StackOverflow\files\root\Nicola-sheperd" - 1
"d:\bat\StackOverflow\files\root\Sara-smith" - 2

==>D:\bat\StackOverflow\28786418.bat bat html>files\28786418.txt

==>type files\28786418.txt
"d:\bat\StackOverflow" - 40
"d:\bat\StackOverflow\files" - 3
"d:\bat\StackOverflow\files\backup_done" - 0
"d:\bat\StackOverflow\files\Roboto" - 0
"d:\bat\StackOverflow\files\root" - 0
"d:\bat\StackOverflow\files\Roboto\backup_done" - 0
"d:\bat\StackOverflow\files\root\Ian-ionescu" - 0
"d:\bat\StackOverflow\files\root\John-doe" - 0
"d:\bat\StackOverflow\files\root\Nicola-sheperd" - 0
"d:\bat\StackOverflow\files\root\Sara-smith" - 0

==>
票数 1
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/28786418

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档