用Prolog获得唯一的结果

Question

我有一个返回：[[vincent,vincent],[vincent,marcellus],[marcellus,vincent],[marcellus,marcellus],[pumpkin,pumpkin],[honey_bunny,honey_bunny]]的Prolog代码。

:- initialization main.

loves(vincent, mia).
loves(marcellus, mia).
loves(pumpkin, honey_bunny).
loves(honey_bunny, pumpkin).

jealous(X, Y) :-
    loves(X, Z),
    loves(Y, Z).

main :- 
    findall([X, Y], jealous(X, Y), L),
    write(L),
    halt.

当X= Y时，如何得到唯一的结果？我尝试了下面的代码以获得与以前相同的结果。

jealous(X, Y) :-
    X \== Y,
    loves(X, Z),
    loves(Y, Z).

和\=在一起，我得到了[]。结果如何只获得[vincent,marcellus]？

Answer 1

你尝试的解决方案中的目标顺序是错误的。当用两个不同的变量调用时，(\==)/2标准谓词总是成功的。解决方案是，只有在实例化谓词的参数时才调用它：

jealous(X, Y) :-
    loves(X, Z),
    loves(Y, Z),
    X \== Y.

使用此修补程序，您的查询现在返回：

?- findall([X, Y], jealous(X, Y), L).
L = [[vincent, marcellus], [marcellus, vincent]].

所以，没人再嫉妒自己了。但你还是有多余的解决方案。我们可以修改jealous/2谓词以对返回的解决方案中的名称进行排序。例如：

jealous(X, Y) :-
    loves(X0, Z),
    loves(Y0, Z),
    X0 \== Y0,
    (   X0 @< Y0 ->
        X = X0, Y = Y0
    ;   X = Y0, Y = X0
    ).

现在，通过使用setof/3而不是findall/3，我们可以得到：

?- setof([X, Y], jealous(X, Y), L).
L = [[marcellus, vincent]].

最后一个观察。列表是表示一对的糟糕的解决方案。传统的方法是使用X-Y或(X, Y)。

Answer 2

只要有可能，就使用dif/2而不是(\==)/2。

dif/2将帮助您编写逻辑合理的程序。

有关详细信息，请看prolog-dif！