方案宏展开显示变量是无界的

Question

当我用小段阅读lisp时，我正在编写一个简单的Lisp解释器，但是现在我被这个错误困住了两个多小时。我正在定义一个局部变量genv，但是仍然会得到这个错误。一定有一些宏观膨胀的东西，我无法理解，我已经检查了扩展使用引用，它似乎是好的。拜托，如果有人能给点启发的话，那就太好了。(代码使用r5rs语言和guile方案)

;; Macro to print it's given arguments line by line and end with a ------
(define-syntax println
  (syntax-rules ()
    ((_ expr expr* ...) (begin (display expr)
                               (newline)
                               (println expr* ...)))
    ((_ expr) (begin (display expr) (newline)))
    ((_) (display "--------\n"))))

(define (evaluate expr env)
  (begin (println "Evaluating" expr)
  (if (not (pair? expr))
      (cond ((symbol? expr) (lookup env expr))
            ((or (number? expr) (string? expr) (char? expr) (boolean? expr) (vector? expr)) expr)
            (else (error "Cannot evaluate" expr)))

      ;; not atom
      (case (car expr)
        ((quote) (cadr expr))

        ;; (define name expr)
        ((define) (update (cadr expr) (caddr expr) env))

        ((if) (if (evaluate (cadr expr) env)
                  (evaluate (caddr expr) env)
                  (evaluate (cadddr expr) env)))

        ((begin) (eprogn (cdr expr) env))

        ((set!) (update (cadr expr) (evaluate (caddr expr) env) env))

        ((lambda) (make-function (cadr expr) (cddr expr) env))

        (else (invoke (evaluate (car expr) env)
                      (evlis (cdr expr) env)))))))

;; Evaluates all the expressions (exprs) in the given environment (env)
(define (eprogn exprs env)
  (if (pair? exprs)

      ;; False when exprs contains just one item
      (if (pair? (cdr exprs))

          (begin (evaluate (car exprs) env)
                 (eprogn (cdr exprs) env))

          (evaluate (car exprs) env))

      '()))


(define (evlis exprs env)
  (if (pair? exprs)
      (cons (evaluate (car exprs) env)
            (evlis (cdr exprs) env))
      '()))

;; Makes a new applicable function, that closes the environment (env)
(define (make-function vars body env)
  (lambda (vals)
    (eprogn body (extend-environment env vars vals))))


(define (invoke fn args)
  (if (procedure? fn)
      (fn args)
      (error "Not a function" fn)))

;; Environment suite

;; Helper macros for working with an environment vector

;; Returns the parent environment of (env)
(define-syntax parent-env-of
  (syntax-rules ()
    ((parent-env-of env) (vector-ref env 0))))

;; Returns the bind-map of (env)
(define-syntax bind-map-of
  (syntax-rules ()
    ((bind-map-of env) (vector-ref env 1))))

;; Sets the parent environment of (env)
(define-syntax set-parent-env!
  (syntax-rules ()
    ((set-parent-env! env parent-env) (vector-set! env 0 parent-env))))

;; Sets the bind-map of (env)
(define-syntax set-bind-map!
  (syntax-rules ()
    ((set-bind-map! env bind-map) (vector-set! env 1 bind-map))))

;; Makes a new environment with the parent env set to (parent-env)
(define (make-new-environment parent-env)
  (let ((new-env (vector #f #f)))
    (begin
      (set-parent-env! new-env parent-env)
      (set-bind-map! new-env '())
      new-env)))

;; Searches for the value of (sym) in (env), raises
;; error if it can't find
(define (lookup env sym)
  (if (null? env)
      (error "Unbound name" sym)
      (let ((val (assoc sym (bind-map-of env))))
        (if (equal? val #f) (lookup (parent-env-of env) sym) (cdr val)))))

;; Create the binding update the (sym)'s value to (value) in the given (env)
(define (update sym value env)
  (begin (println "Called update with env: " env "sym: " sym "value: " value)
         (define new-bind-map (assoc-set! (bind-map-of env) sym value))
         (set-bind-map! env new-bind-map)))

;; Extends an (env) by creating a new environment and setting the
;; bindings specified by the list of symbols (vars) and the
;; list of values (vals)
(define (extend-environment vars vals env)
  (define new-env (make-new-environment env))
  (update-all vars vals env))

;; Helper function
(define (update-all vars vals env)
  (cond ((pair? vars) (if (not (pair? vals))
                          (error "More symbols than values to bind with")
                          (begin (update (car vars) (car vals) env)
                                 (extend (cdr vars) (cdr vals) env))))
        ((null? vars) (if (not (null? vals))
                          (error "More values than symbols to bind with")
                          env))))

;; Helper macros for initializing the global env bind map

有问题的代码：

;; ------------PROBLEM IN THESE MACROS------------------

(define-syntax _def-initial
  (syntax-rules ()
    ((_def-initial name)
     (update 'name 'void genv))
    ((_def-initial name value)
     (update 'name value genv))))

(define-syntax _def-primitive
  (syntax-rules ()
    ((_def-primitive name value arity)
     (_def-initial name (lambda (args)
                          (if (equal? arity (length args))
                              (apply value args)
                              (error "Incorrect arity" (list 'name value))))))))

(define-syntax _fill-global-env
  (syntax-rules ()
    ((_fill-global-env)
     (begin
       (println "Filling the environment")
       (_def-primitive + (lambda (x y) (+ x y)) 2)
       (_def-primitive - (lambda (x y) (- x y)) 2)
       (_def-primitive * (lambda (x y) (* x y)) 2)
       (_def-primitive / (lambda (x y) (/ x y)) 2))
    )))


;; Racket and Guile SAY genv IS UNBOUND

(define get-global-environment
  ;; name must be `genv' coz of the above macros
  (let ( (genv #f) )
    (lambda ()
      (if (equal? genv #f) ;; If uninitialized
          (begin (set! genv (make-new-environment '()))
                 (println "Before filling: "genv)
                 (_fill-global-env)
                 (println "After filling: " genv)
                 genv)
          genv))))

;; ------------------- END OF PROBLEMATIC CODE(IT SEEMS) ---------------

继续：

;; - Start the interpreter
(define (main args)
  ;; Define the global environment
  (define genv (get-global-environment))
  (println "Global environment: " genv)
  (let loop ((expr (read (current-input-port))))
    (if (eof-object? expr)
        (println "Done")
        (begin (println (evaluate expr genv))
               (loop (read (current-input-port)))))))

(main "")

下面是我从Racket收到的错误(在有问题的代码的get-global-environment's体内，而不是在main的体内)：

. . genv: undefined;
 cannot reference undefined identifier

Answer 1

方案宏是http://en.wikipedia.org/wiki/Hygienic_macro。您在get-global-environment中定义的get-global-environment与您的_def-initial中的genv不一样(在定义_def-initial时，它使用的是任何genv，在本例中它将是顶级的，正如您指出的那样，这是不存在的)。

为了使宏工作，必须使_fill-global-env、_def-primitive和_def-initial都接受genv参数，以便_def-initial使用该genv而不是顶层的genv。