变量打印注册表批处理CSV

Question

在通过cmd查询以下内容时

REG QUERY "HKCU\Printers\Connections"

产出如下：

HKEY_CURRENT_USER\Printers\Connections\,,xxx-SD-KDP11,Colour
HKEY_CURRENT_USER\Printers\Connections\,,xxx-SD-KDP11,Mono

但是，当运行包含以下代码的批处理文件时

@echo OFF
setlocal enableextensions enabledelayedexpansion 
echo ============================
echo Network Printers ...
if exist network_printers.txt del network_printers.txt
if exist network_printers2.txt del network_printers2.txt

set reg_keys=
set blank=
set printers_network_paths=
set printers_network_types=

REG QUERY "HKCU\Printers\Connections" > network_printers.txt

for /f "tokens=* delims=" %%A in ('type network_printers.txt') do set network_printers_init=!network_printers_init! %%A
echo !network_printers_init! > network_printers2.txt
echo !network_printers_init!
pause

for /f "usebackq tokens=1,* delims=, skip=4" %%a in ('network_printers2.txt') do (
  set reg_keys = !reg_keys! %%a
)

for /f "tokens=2,* delims=, skip=4" %%a in ('type network_printers2.txt') do (
  set blank = !blank! %%b
)

for /f "tokens=3,* delims=, skip=4" %%a in ('type network_printers2.txt') do (
  set printers_network_names = !printers_network_names! %%c
)

for /f "tokens=4,* delims=, skip=4" %%a in ('type network_printers2.txt') do (
  set printers_network_types = !printers_network_types! %%d
)

echo reg_keys: !reg_keys!
echo blank: !blank!
echo Network Printers paths: !printers_network_names!
echo Network Printers types: !printers_network_types!

echo Network Printers paths: !printers_network_names! >> %file%
echo Network Printers types: !printers_network_types! >> %file%
pause

生成的.csv文件没有任何意义!printers_network_names！还有!printers_network_types！另外，echo行显示在最后4个变量中没有存储任何内容。

请指点？

Answer 1

在for /f循环中，"skip=4"意味着跳过4行，但是network_printers2.txt只包含一行。

还有一些其他的东西可以改进。主要是，当您在批处理脚本中设置变量时，您应该使用set "varname=string"，它的引号是这样的，并且没有围绕=的空格。您也可以在没有中间文本文件和type的无用使用的情况下做您需要的事情。

我不完全确定您希望最终结果是什么，但看起来您的脚本比需要的要复杂得多。

@echo OFF
setlocal enableextensions enabledelayedexpansion 
echo ============================
echo Network Printers ...

for /f "tokens=2* delims=," %%A in ('REG QUERY "HKCU\Printers\Connections"') do (
    set "printers_network_names=!printers_network_names! %%A"
    set "printers_network_types=!printers_network_types! %%B"
)

echo Network printer paths: !printers_network_names!
echo Network printer types: !printers_network_types!

结果：

============================
Network Printers ...
Network printer paths:  xxx-SD-KDP11 xxx-SD-KDP11
Network printer types:  Colour Mono