即使有预期的输入，Antlr4也会打印“外部输入”错误。

Question

我正在尝试使用笑脸规范解析OpenSMILES字符串。

语法：

grammar SMILES;

atom: bracket_atom | aliphatic_organic | aromatic_organic | '*';

aliphatic_organic: 'B' | 'C' | 'N' | 'O' | 'S' | 'P' | 'F' | 'Cl' | 'Br' | 'I';
aromatic_organic: 'b' | 'c' | 'n' | 'o' | 's' | 'p';

bracket_atom: '[' isotope? symbol chiral? hcount? charge? atom_class? ']';
symbol: element_symbols | aromatic_symbols | '*';
isotope: NUMBER;
element_symbols: UPPER_CASE_CHAR LOWER_CASE_CHAR?;
aromatic_symbols: 'c' | 'n' | 'o' | 'p' | 's' | 'se' | 'as';

chiral: '@'
        |  '@@'
        |  '@TH1' | '@TH2'
        |  '@AL1' | '@AL2'
        |  '@SP1' | '@SP2' | '@SP3'
        |  '@TB1' | '@TB2' | '@TB3' | DOT DOT DOT | '@TB29' | '@TB30'
        |  '@OH1' | '@OH2' | '@OH3' | DOT DOT DOT | '@OH29' | '@OH30';

hcount: 'H' |  'H' DIGIT;

charge: '-'
        |  '-' DIGIT
        |  '+'
        |  '+' DIGIT
        |  '--'
        |  '++';

atom_class:':' NUMBER;

bond: '-' | '=' | '#' | '$' | ':' | '/' | '\\';
ringbond: (bond? DIGIT |  bond? '%' DIGIT DIGIT);
branched_atom: atom ringbond* branch*?;
branch: '(' chain ')' |  '(' bond chain ')' |  '(' dot chain ')';
chain: branched_atom
    |  chain branched_atom
    |  chain bond branched_atom
    |  chain dot branched_atom;
dot: '.';

DOT: .;
DIGIT: [0-9];
NUMBER: DIGIT+;
UPPER_CASE_CHAR: [A-Z];
LOWER_CASE_CHAR: [a-z];

ONE_TO_NINE: [1-9];

smiles: chain;

WS: [ \t\n\r]+ -> skip ;

当尝试使用AntlrWorks2 2的TestRig解析以下内容时：

CCc(c1)ccc2[n+]1ccc3c2Nc4c3cccc4

打印下列错误(缩写为简洁)：

line 1:5 extraneous input '1' expecting {'*', '[', 'N', 'O', 'I', 'S', '%', ')',..., DIGIT}
...
line 1:31 extraneous input '4' expecting {<EOF>, '*', '[', 'N', 'O',..., DIGIT}

在字符串中遇到的每个数字都会发生这种情况。

编辑1

按照@Lucas Trzesniewski的建议，修正了DOT规则之后，extraneous input错误消失了。然而，当测试不同的微笑字符串时，现在出现了一个新的错误。

例如，测试：

[Cu+2].[O-]S(=O)(=O)[O-]

产生错误：

line 1:1 no viable alternative at input 'C'

编辑2

编辑1的问题是由于我的element_symbols规则造成的。使用文字符号字符串似乎解决了这个问题。

element_symbols: 'H' | 'He' | 'Li' | 'Be' | 'B' | 'C' | 'N' | 'O' | 'F' | 'Ne' | //...and so on

Answer 1

你的规则是错的。

第一个错误：

DOT: .;

这是个完美无缺的案子。你真正的意思是：

DOT: '.';

第二个错误:您被以下规则搞混了：

DIGIT: [0-9];
NUMBER: DIGIT+;
ONE_TO_NINE: [1-9];

ONE_TO_NINE永远不会与任何东西相匹配，因为它包含在DIGIT中，而DIGIT首先出现。因为从来没有使用过ONE_TO_NINE规则，所以您应该简单地删除它。

然后，解析器规则中的DIGIT DIGIT之类的内容也不匹配，如果您期望有一个2位数的数字，那么您将在那里得到一个NUMBER令牌，除非您用空格分隔数字(我不知道您在那里的真正意思是什么，也许这不是错误)。