首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >按空格后的第一个字符对TStringList进行排序

问按空格后的第一个字符对TStringList进行排序
EN

Stack Overflow用户
提问于 2014-09-24 11:38:52
回答 3查看 317关注 0票数 1

我在德尔菲有一个TStringList。插入项目后,我将调用.sort过程对项目进行排序。项目是先名后姓。例如:“约翰·史密斯”。我想按姓氏对这些物品进行排序。我指的是在空格之后的第一个角色。我该怎么做?

此外,这些项可能是unicode字符串,如波斯字符。

EN

回答 3

Stack Overflow用户

回答已采纳

发布于 2014-09-24 12:50:24

我会使用CustomSort方法TStringList来提供一个定制的比较函数。首先,让我们想象一下,我们已经得到了比较函数:

代码语言:javascript
复制
function NameCompareFunc(List: TStringList; Index1, Index2: Integer): Integer;
begin
  Result := ...;
end;

这个函数(在适当的时候)将负值返回为“小于”,“正”返回为“大于”,“零”返回为“等于”。

然后我们对列表进行如下排序:

代码语言:javascript
复制
List.CustomSort(NameCompareFunc);

所以,这是很容易做到的。但是我们如何实现NameCompareFunc呢?首先,让我们把这个名字分成姓和剩下的。

代码语言:javascript
复制
procedure SplitName(const Name: string; out Last, Rest: string);
var
  P: Integer;
begin
  P := Pos(' ', Name);
  if P = 0 then begin
    Last := Trim(Name);
    Rest := '';
  end else begin
    Last := Trim(Copy(Name, P+1, MaxInt));
    Rest := Trim(Copy(Name, 1, P-1));
  end;
end;

这是一个非常天真的方式来分割一个名字。您可能希望从名称的末尾开始搜索分隔符,但我将让您决定如何这样做。

现在,我们可以实现比较功能:

代码语言:javascript
复制
function NameCompareFunc(List: TStringList; Index1, Index2: Integer): Integer;
var
  Last1, Last2, Rest1, Rest2: string;
begin
  SplitName(List[Index1], Last1, Rest1);
  SplitName(List[Index2], Last2, Rest2);
  Result := AnsiCompareText(Last1, Last2);
  if Result = 0 then begin
    Result := AnsiCompareText(Rest1, Rest2);
  end;
end;

一些注意事项:

  1. 我认为名字比较应该总是不区分大小写的。
  2. 我们使用AnsiCompareText执行区域设置感知的比较。
  3. 如果我们遇到两个姓氏相同的名字,那么我们就实现了与其他名字的二次比较。
票数 5
EN

Stack Overflow用户

发布于 2014-09-24 12:32:18

您可以使用Stringlist的CustomSort方法:

代码语言:javascript
复制
function LastNameCompareStrings(List: TStringList; Index1, Index2: Integer): Integer;
var
  S1, S2: string;
  SpaceIndex: Integer;
begin
  S1 := List[Index1];
  SpaceIndex := Pos(' ', S1);
  if SpaceIndex <> 0 then
    S1 := Copy(S1, 1, SpaceIndex - 1);

  S2 := List[Index2];
  SpaceIndex := Pos(' ', S2);
  if SpaceIndex <> 0 then
    S2 := Copy(S2, 1, SpaceIndex - 1);

  if List.CaseSensitive then
    Result := AnsiCompareStr(S1, S2)
  else
    Result := AnsiCompareText(S1, S2);
end;

procedure TForm7.ButtonFirstNameClick(Sender: TObject);
begin
  NameBuffer.Sort;
  Memo1.Lines.Assign(NameBuffer);
end;

procedure TForm7.ButtonLastNameClick(Sender: TObject);
begin
  NameBuffer.CustomSort(@LastNameCompareStrings);
  Memo1.Lines.Assign(NameBuffer);
end;

我举个例子,我在一个名为StringList的NameBuffer中有你们所有的名字。然后,我在表单中添加了两个按钮,对我的列表进行排序,并在屏幕上显示结果。

票数 3
EN

Stack Overflow用户

发布于 2014-09-24 11:54:23

您可以遍历StringList的每一项(让我们称其为FullNames),拆分每个字符串,并将“拆分”放入两个新的单独的字符串列表中,您可以称之为FirstNameList和LastNameList。

现在,创建第三个可以称为ReverseFirstLast的字符串列表,并将来自LastNameList的项与FirstNameList组合起来,并将它们放入ReverseNames中。

现在你把所有的名字都按反序排列。姓先,姓后。

现在,您可以对ReverseFirstLast进行排序,并再次执行拆分和组合方法,以再次逆转订单并维护排序。

这是一种方法,以获得一个粗糙的方法和运行。

票数 0
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/26015964

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档