如何将条件格式应用于仅可见的单元格？

Question

我正在使用Excel-2010，我已经为Excel范围A1:F 100应用了3 3scale条件格式，在下拉宏上隐藏/取消隐藏将被激活，而隐藏/取消隐藏不是连续的，例如：-行1,10,30,54,67,88可能仅可见。

因此，仅对于这些可见行，相同的条件格式应该可以工作。

我试着浏览以找到它，但是我没有得到所需的东西。

帮助是非常感谢的。

提前谢谢。

Answer 1

正如所评论的那样，应该是这样的：

Sub ject()
    Dim rng As Range
    With Sheet1 '~~> change to your actual sheet
        .Range("A1:F100").FormatConditions.Delete
        Set rng = .Range("A1:F100").SpecialCells(xlCellTypeVisible)
        .Range("A1").FormatConditions.AddColorScale 3
        With .Range("A1").FormatConditions(1)
            With .ColorScaleCriteria(1)
                .Type = xlConditionValueLowestValue
                .FormatColor.Color = RGB(255, 0, 0)
            End With
            With .ColorScaleCriteria(2)
                .Type = xlConditionValuePercentile
                .FormatColor.Color = RGB(255, 255, 0)
            End With
            With .ColorScaleCriteria(3)
                .Type = xlConditionValueHighestValue
                .FormatColor.Color = RGB(0, 255, 0)
            End With
            .ModifyAppliesToRange rng
        End With
    End With
End Sub

每次运行或调用此例程时，它都会重新将格式应用于可见范围。

它可以合并到现有代码中，也可以单独运行。HTH。

Answer 2

有一种可能性，小计公式的最小，中点和最大值。

最小值: Type = =SUBTOTAL(105,$A$1:$F$100)

中点:类型=公式，=MEDIAN(IF((SUBTOTAL(103,INDIRECT("A"&ROW($1:$100)))>0)*($A$1:$F$100<>""),$A$1:$F$100))

最大值: Type = =SUBTOTAL(104,$A$1:$F$100)

如果您可以接受这些值的平均值，而不是50%百分位数作为中点，则中点的公式将更简单：

=SUBTOTAL(101,$A$1:$F$100)

问候

Axel