Weibull分布的SAS Randgen调用

Question

我试图在proc中调用随机元来创建10个随机数，这些随机数遵循Weibull分布，并具有一定的参数。下面是我使用的代码(显然不止一个循环，但我现在只是在测试)：

do i = 1 to 1;
    Call randgen(Rands[i,1:Ntimes], 'Weibull', alpha[i], beta[i]);
    print (rands[1,1:Ntimes]);
    print (alpha[i]) (beta[i]);
end;

对于本例，Ntimes = 10，alphai = 4.5985111，betai = 131.79508。我的问题是，10个迭代/随机数中的每一个都返回为1。我在R中使用了rweibull函数，得到了有意义的结果，所以我认为它与SAS或我的代码有关，而不是与参数有关。我正确地使用了Randgen电话吗？有人知道为什么结果会是这样吗？

Answer 1

这样做是可行的：

proc iml;
 alpha=j(10);
 beta=j(10);
 alpha[1]=4.59;
 beta[1] = 131.8;
 Ntimes=10;
 rands = j(1,10);
 print (rands);
 do i = 1 to 1;
    Call randgen(Rands, 'WEIB', alpha[1],beta[1]);
    print (rands);
 end;
quit;

我不认为你可以那样使用Rands[1:Ntimes]。我想你应该把它分配给一个临时矩阵，然后把这个矩阵的结果分配给一个更大的矩阵。

IE：

allRands=j(10,10);
do i = 1 to 10;
    Call randgen(Rands, 'WEIB', alpha[1],beta[1]);
    print (rands);
    allRands[i,1:10]=Rands;
end;
print(allRands);

Answer 2

实际上，除非您使用的是一个古老版本的SAS/IML，否则您不需要任何循环。自SAS/IML 12.3，RANDGEN子例程接受参数向量。.在您的例子中，为alpha和beta参数定义一个向量。假设有“Nparam”参数。然后分配一个N矩阵来保存结果。通过对RANDGEN的单个调用，您可以填充矩阵，以便i_th列是来自威布尔(alphai，betai)的大小为N的示例，如下面的示例所示：

 proc iml;
 Nparam = 8; N = 1000;

 alpha= 1:Nparam;  /* assign parameter values */
 beta = 10 + (Nparam:1);
 rands = j(N,Nparam);
 call randgen(rands, 'WEIB', alpha,beta);  /* SAS/IML 12.1 */

 /* DONE. The i_th column is a sample from Weibul(alpha[i], beta[i]) 
    TEST IT: Compute the mean of each sample: */
 mean = mean(rands); std = std(rands);
 print (alpha//beta//mean//std)[r={"alpha" "beta" "mean" "std"}];
 /* TEST IT: Plot the distribution of each sample (SAS/IML 12.3) */  
 title "First param"; call histogram(rands[,1]);
 title "Last param";  call histogram(rands[,Nparam]);