批处理脚本如何从字符串中识别变量

Question

我希望批处理脚本从配置文件中读取vars。

我想在配置文件中使用var。

因此，我将下面的内容放入我的配置文件eval.ini中

Universal:=C:\Universal
Galaxy:=%Universal%\Galaxy
Sagittarius:=%Universal%\Sagittarius
Canis Major:=%Universal%\Canis Major
Sun:=%Galaxy%\Sun
Sirius:=%Canis Major%\Sirius

因此，如何使批处理脚本识别配置文件中的这些var。

现在，我如何使它工作的方式是逐行读取"eval.ini“，并将一行拆分成一个var名称和一个var值。

Galaxy:=%Universal%\Galaxy    ==>>    Galaxy    %Universal%\Galaxy

并将它们放入一个混合的临时批处理脚本中如下所示：

SET "Galaxy=%Universal%\Galaxy"

然后我调用临时批处理脚本来设置所有的vars。而且它是有效的。

看起来不错，但我只是不喜欢创建一个临时批处理脚本文件来完成这个任务。

请告诉我其他的方法。

我的批量脚本"eval.bat"：

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION

:SOA
    SET "confile=%~dpn0.ini"
    SET "setvar=%temp%\%~n0_setvar.bat"
    SET "varlist="

    ECHO/>%setvar%
    FOR /F "usebackq tokens=1,* eol=; delims=:=" %%a in ("%confile%") do (
        IF NOT "!varlist!" == "" (
            SET "separator= "
        ) else (
            SET "separator="
        )
        SET "varlist=!varlist!!separator!^"%%a^""
        ECHO/SET "%%a=%%b">>%setvar%
    )
    CALL "%setvar%" && del/q/f "%setvar%" || GOTO:EOA
    FOR %%a in (%varlist%) do (
        ECHO/%%~a = !%%~a!
    )

:EOA
    ENDLOCAL
    EXIT/B

产出：

Universal = C:\Universal
Galaxy = C:\Universal\Galaxy
Sagittarius = C:\Universal\Sagittarius
Canis Major = C:\Universal\Canis Major
Sun = C:\Universal\Galaxy\Sun
Sirius = C:\Universal\Canis Major\Sirius

Answer 1

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION

:SOA
SET "confile=q24928414.txt"
SET "setvar=%temp%\%~n0_setvar.bat"
SET "varlist="

FOR /F "usebackq tokens=1*delims=:=" %%a in ("%confile%") do (
 CALL SET "%%a=%%b"
 ECHO %%a = !%%a!
)

:EOA
GOTO :EOF

为了适应我的系统，我用q24928414.txt替换了您的输入文件。

为我工作！

-MC ND回复后编辑