机器人框架:使用faker为帐户数据生成前缀字符串。

Question

我正在编写测试用例，测试添加帐户的功能。这意味着我需要生成帐户的数据:姓名，电子邮件，参考编号和订单编号。我在想，对于这些字段中的每一个，我只需生成一个带有前缀的随机单词或数字，这样我就可以使用脚本定期从数据库中删除这些条目。

问题是，我不知道如何添加前缀，或者实际上只是使用faker的大部分关键字。

在使用md5关键字为测试用例的每个实例创建一个字符串时，我在资源文件中创建了一个变量：

*** Variables ***
${md5}                MD 5

然后，每当我想要写前缀时，我就调用这个变量(我在各个字段的末尾调用它，例如。电子邮件: email+${md5}@gmail.com，参考: test ${md5}

*** Keywords ***
Write username
    Input Text    a11y-username    test ${md5}

我不知道实际的文档是在哪里使用faker从机器人框架，我使用http://fake-factory.readthedocs.org/en找到我想要使用的提供者，然后努力让他们从射频工作。

有人能帮我让random_int()工作吗?或者向我指出RF中所有虚假供应商的相关文档。

提前谢谢。

Answer 1

概述

使用faker关键字只需调用它们，并将结果保存在变量中即可。不能在变量表中使用faker关键字，需要在testcase或关键字中使用它们。但是，您可以使用python变量文件直接调用faker命令。

例如，要获得一个地址，您可以调用Address关键字。因为假关键字是如此通用，我建议完全限定关键字，以清楚地表明您正在生成假数据。

例如：

*** Settings ***
| Library | FakerLibrary | WITH NAME | faker

*** Test Cases ***
| Example of using faker
| | ${address}= | faker.Address
| | log | address: ${address}

使用随机Int关键字

若要获取随机整数，请使用随机整数关键字：

| Example of using faker to get a random integer
| | ${number}= | faker.Random Int
| | log | my number is ${number}

初始化整个套件的变量

如果要对整个套件使用相同的值，可以编写一个关键字，该关键字使用集组变量关键字设置某些套件级变量。

例如：

*** Settings ***
| Library | FakerLibrary | WITH NAME | faker
| Suite Setup | Initialize Test Data

*** Test Cases ***
| Example of using faker to initialize suite variables
| | log | The suite address is ${address}
| | log | The suite md5 is ${md5}
| | log | The suite number is ${number}


*** Keywords ***
| Initialize test data
| | ${address}= | faker.Address
| | ${md5}= | faker.MD5
| | ${number}= | faker.Random Int
| | 
| | Set suite variable | ${address}
| | Set suite variable | ${md5}
| | Set suite variable | ${number}

文档

FakerLibrary关键字文档可在https://guykisel.github.io/robotframework-faker/上获得。