在VBA中求和范围

Question

我不是很精通编码，所以这可能不是正确的术语，但我试图做一个非常简单的事情，和范围。我的意思是我想：

Sub Test()
Range("E2:E9") = Range("D2:D9") + Range("G2:G9")
End Sub

如果我只使用：

Sub Test()
Range("E2") = Range("D2") + Range("G2")
End Sub

由此，我想要做的就是让细胞E2-E9中的所有东西都等于它的D_和G_的相对加法。例如，E4将等于D4+G4。

这只是对一个带有100+行的大型项目的测试，这就是为什么我不想全部手工完成的原因。

也许我需要使用某种数组加法什么的？我不确定。

Answer 1

使用以下Range Object Formula属性：

Edit1:避免循环引用，正如Mark所指出的

With Range("E2:E9")
    .Offset(0, 2).Value = .Offset(0, 2).Value '~~> avoid circular ref
    .Formula = "=D2+G2"
    .Value = .Value
    .Offset(0, -1).ClearContents
    .Offset(0, 2).Formula = "=E2" '~~> if you still want to have it reflected in G
End With

或者，您可以直接将D添加到E，而无需使用辅助列G。

With Range("E2:E9")
    .Offset(0, -1).Copy '~~> copy what's in D
    .PasteSpecial xlPasteValues, xlPasteSpecialOperationAdd '~~> add in E
    .Offset(0, -1).ClearContents '~~> clear whatever's in D
End With

Answer 2

下面是如何将其作为数组函数来实现的：

Range("E2:E9").FormulaArray = "=D2:D9+G2:G9"

但是数组函数可能很难处理，所以您可能只想将其作为单细胞公式来执行：

Range("E2:E9").Formula = "=D:D+G:G"

Excel做了一点神奇的工作，使这个公式有效。如果您想要显式地：

Range("E2:E9").FormulaR1C1 = "=RC[-1]+RC[2]"

Answer 3

您可以为此制定一个自定义公式。

例如，您想要将A1:A10和B1:B10相加，并需要C1:C10中的结果(请注意，这里需要相同的行数，两者都是垂直的)

Sub AddRanges(Rng1 As Range, Rng2 As Range, ResultRng As Range)
    Dim i As Long, N As Long
    N = Rng1.Rows.Count

    For i = 1 To N
        ResultRng(i, 1).Value = Rng1(i, 1).Value + Rng2(i, 1).Value
    Next i
End Sub

此公式调用上述子例程。

Sub TestMyFormula()
    Dim RngA As Range, RngB As Range, RngC As Range
    Set RngA = ActiveSheet.Range("A1:A10")
    Set RngB = ActiveSheet.Range("B1:B10")
    Set RngC = ActiveSheet.Range("C1:C10")

    Call AddRanges(RngA, RngB, RngC)

End Sub