是否可以使用迭代增量在类型化的教会数字上实现加法？

Question

我无法找到一种将加法定义为重复增量的方法，尽管在一种非类型化的语言中可以这样做。这是我的代码：

{-# LANGUAGE RankNTypes #-}
type Church = forall a . (a -> a) -> (a -> a)

zero :: Church
zero = \f -> id

inc :: Church -> Church
inc n = \f -> f . n f

-- This version of addition works
add1 :: Church -> Church -> Church
add1 n m = \f -> n f . m f

-- This version gives me a compilation error
add2 :: Church -> Church -> Church
add2 n m = n inc m

我为add2获得的编译错误是

Couldn't match type `forall a1. (a1 -> a1) -> a1 -> a1'
                  with `(a -> a) -> a -> a'
    Expected type: ((a -> a) -> a -> a) -> (a -> a) -> a -> a
      Actual type: Church -> (a -> a) -> a -> a
    In the first argument of `n', namely `inc'
    In the expression: n inc m
    In an equation for `add2': add2 n m = n inc m

为什么这是个错误？Church不是((a->a) -> a -> a)的同义词吗？

Answer 1

不管我添加了什么额外的类型注释，我都无法让您的代码键入，尽管我可能不够聪明。(我还尝试添加ImpredicativeTypes。)我认为这里的问题是在定义中

type Church = forall a. (a -> a) -> (a -> a)

a只能用秩-0类型实例化(即没有foralls在内部)，而Church本身并不是，所以不能将这样定义的教会数字应用到inc中。

然而，有一个相对简单的解决方法，它稍微冗长，但使所有事情都很好地工作，否则:将Church变成一个新类型，而不是一个类型，这样就可以从外部把它看作是单形的。以下所有工作：

{-# LANGUAGE RankNTypes #-}
newtype Church = Church { runChurch :: forall a . (a -> a) -> (a -> a) }

zero :: Church
zero = Church (\f -> id)

inc :: Church -> Church
inc n = Church (\f -> f . runChurch n f)

add2 :: Church -> Church -> Church
add2 n = runChurch n inc