回声内部的回声

Question

我试图得到一个由另外两个变量组成的变量的值。让它工作的唯一方法是在/F开关中使用FOR命令并打开第二个命令shell：

SET A=This
SET B=That
SET ThisThat=YES!

FOR /F %I IN ('ECHO %A%%B%') DO cmd.exe /C ECHO %%I%

输出：

C:\>cmd.exe /c echo %ThisThat%
YES!

有谁知道一个更优雅的方法吗？

更新

这里有一个更好的解释，说明我想要完成什么(并且能够用你们的--尤其是Aacini的回应来完成)

对于Rational BuildForge项目，我为每个部署目标主机定义了环境变量。示例：

CURAM_HOST_NAME_DEV=DDW5T
CURAM_HOST_NAME_UAT=DUW5T
CURAM_HOST_NAME_TRN=DTW5T
CURAM_HOST_NAME_PRD=DPW5P

另一个变量主机包含要部署到的环境。部署代码对于所有部署目标都是通用的，并且使用变量CURAM_HOST_NAME，因此我需要将这个变量设置为对应于部署到的主机的变量的值。以下是其中的诀窍：

@ECHO OFF

SET CURAM_HOST_NAME_DEV=DDW5T
SET CURAM_HOST_NAME_UAT=DUW5T
SET CURAM_HOST_NAME_TRN=DTW5T
SET CURAM_HOST_NAME_PRD=DPW5P

SET HOST=DEV
CALL ECHO %%CURAM_HOST_NAME_%HOST%%%
SET HOST=UAT
CALL ECHO %%CURAM_HOST_NAME_%HOST%%%
SET HOST=TRN
CALL ECHO %%CURAM_HOST_NAME_%HOST%%%
SET HOST=PRD
CALL ECHO %%CURAM_HOST_NAME_%HOST%%%

输出：

DDW5T
DUW5T
DTW5T
DPW5P

在BuildForge步骤中，设置此特定变量的代码如下所示：

.bset env "CURAM_HOST_NAME=`CALL ECHO %%%CURAM_HOST_NAME_%%HOST%%%%`"

( BF解析器需要额外的%s)

对于主机变量的DEV值，这将在日志中产生以下结果：

1026 5/3/14 7:34 PM STEP .bset env "CURAM_HOST_NAME=`CALL ECHO %%%CURAM_HOST_NAME_%%HOST%%%%`"
1027 5/3/14 7:34 PM EXEC .bset env 'CURAM_HOST_NAME' = 'DDW5BTH

非常感谢大家。希望我有这样的名声，能让我对你的答案投出更高的分数！

乔泽夫

Answer 1

@echo off

SET A=This
SET B=That
SET ThisThat=YES!

call echo %%%A%%B%%%

编辑：更新回答更新的问题！

@ECHO OFF

SET CURAM_HOST_NAME_DEV=DDW5T
SET CURAM_HOST_NAME_UAT=DUW5T
SET CURAM_HOST_NAME_TRN=DTW5T
SET CURAM_HOST_NAME_PRD=DPW5P

for %%a in (DEV UAT TRN PRD) do CALL ECHO %%CURAM_HOST_NAME_%%a%%

但是，您应该注意到！变量！替换(与setlocal EnableDelayedExpansion一起)的运行速度比CALL echo %%variable%%技巧快得多：

@ECHO OFF
setlocal EnableDelayedExpansion

SET CURAM_HOST_NAME_DEV=DDW5T
SET CURAM_HOST_NAME_UAT=DUW5T
SET CURAM_HOST_NAME_TRN=DTW5T
SET CURAM_HOST_NAME_PRD=DPW5P

for %%a in (DEV UAT TRN PRD) do ECHO !CURAM_HOST_NAME_%%a!

也许你想回顾一下this post

Answer 2

@echo off
setlocal enableDelayedExpansion
set "A=this"
set "B=that"
set "thisthat=YES^!"

echo !%A%%B%!

请注意，感叹号必须在赋值时转义，因为启用了延迟扩展。