包括程序集80x86中的文件

Question

我只是在学习集会，我做了一个简单的程序。但是，我如何将该过程放在一个单独的文件中，以及如何将其包含在main.asm中？

simple proc 
    .
    .
    .
simple ENDP

让我们说，这是我想要纳入的主要程序。我会做什么文件类型，.asm还是.h？

另外，如何在我的main.asm中调用该函数？

Answer 1

您还没有指定您使用的是哪个汇编程序，但是下面是如何使用MASM32：

在.inc文件中声明外部过程的原型；让我们称之为external.inc

; Declare a procedure prototype that takes two DWORD arguments

external_adder PROTO :DWORD, :DWORD

然后在相应的.asm文件中定义这些过程的主体；让我们称之为external.asm

.686p
.model flat,stdcall
option casemap:none

.code

; Define the body of external_adder

external_adder PROC arg1:DWORD, arg2:DWORD
    mov eax,arg1
    add eax,arg2
    ret
external_adder ENDP

END

每当您想从另一个.asm文件中使用这些过程之一时，都会包含.inc文件。让我们创建另一个名为main.asm的文件

.686p
.model flat,stdcall 
option casemap:none

include \masm32\include\kernel32.inc    ; for ExitProcess
include \masm32\include\msvcrt.inc      ; for crt_printf
include external.inc                    ; for external_adder

includelib \masm32\lib\kernel32.lib
includelib \masm32\lib\msvcrt.lib

.data

format db "123 + 456 = %d",13,10,0

.code

start:

invoke external_adder,123,456

; Print the result, then close down the program
invoke crt_printf, ADDR format, eax
invoke ExitProcess,0

END start

要构建这个系统，您可以这样做：

ml /c /coff main.asm
ml /c /coff external.asm
link /SUBSYSTEM:CONSOLE main.obj external.obj