Gradle WAR插件:如何找到要复制的文件的目标

Question

我一直致力于让Gradle生成一个IntelliJ WAR工件定义，作为这篇博客文章 'idea‘任务的一部分。到目前为止，这已经非常成功了，尽管我的代码非常脏，所以我试图清理它。就我而言，war任务应该包含在IntelliJ中创建必要标记所需的所有信息。例如，给定一个Gradle Project对象，比如gradleProject，我可以这样做：

def artifactManager = project.component.find { it.@name == 'ArtifactManager' } as Node
if (artifactManager) {
  Node artifact = artifactManager.artifact.find { it.@type == 'exploded-war' }
  if (artifact) {
    artifactManager.remove(artifact)
  }
} else {
  artifactManager = project.appendNode('component', [name: 'ArtifactManager']);
}
def builder = new NodeBuilder();
def artifact = builder.artifact(type: 'exploded-war', name: "${gradleProject.name} exploded war") {
  'output-path'("${gradleProject.buildDir}/${gradleProject.name}-exploded.war")
  root(id: 'root') {
    element(id: 'directory', name: 'WEB-INF') {
      // copy web.xml
      element(id: 'file-copy', path: gradleProject.war.webXml)
      Set<String> excludeJars = [] as Set
      element(id: 'directory', name: 'classes') {
        // copy classes
        element(id: 'module-output', name: gradleProject.name)
        // copy depending projects module output (classes)
        gradleProject.configurations.runtime.allDependencies.each {
          if (it.hasProperty('dependencyProject')) { // TODO: make it functional?!?
            if (it.dependencyProject.hasProperty('jar'))
              excludeJars.add(it.dependencyProject.jar.archiveName)
            element(id: 'module-output', name: it.dependencyProject.name)
          }
        }
      }
      // copy dependency jars excluding possible existing module jars (not sure it's necessary)
      element(id: 'directory', name: 'lib') {
        // TODO: this should handle ALL kinds of dependencies
        gradleProject.configurations.runtime.each {
          if (!excludeJars.contains(it.name))
            element(id: 'file-copy', path: it)
        }
      }
    }
  }
}
artifactManager.append artifact

修改或创建我的IntelliJ .ipr文件。现在，我在Gradle脚本中向我的WAR工件添加了一些文件，如下所示：

war{
  from project(':rest').file('resource/some.properties')
  from project(':some_project').fileTree('some_folder')
  metaInf {
    from parent.file('build/config/website/' + environment + '/context.xml')
  }
}

我想添加一些Groovy代码来获取这些文件，并创建正确的XML标记，让IntelliJ将它们复制到正确的位置。最简单的方法是什么？我试着玩了以下游戏：

gradleProject.war.source.each { // ... create tags etc.  }

但是源文件列表包括所有的文件，不管它们的目的地是什么(所有libs、web.xml、类等等)。

我怎样才能实现我想要做的事情？

Answer 1

在Gradle博士的帮助下，我终于想出了答案，还有一些尝试和错误。我使用以下代码获得了所需的结果：

def artifactManager = project.component.find { it.@name == 'ArtifactManager' } as Node
if (artifactManager) {
  Node artifact = artifactManager.artifact.find { it.@type == 'exploded-war' }
  if (artifact) {
    artifactManager.remove(artifact)
  }
} else {
  artifactManager = project.appendNode('component', [name: 'ArtifactManager']);
}
def builder = new NodeBuilder();
def artifact = builder.artifact(type: 'exploded-war', name: "${gradleProject.name} exploded war") {
  'output-path'("${gradleProject.buildDir}/${gradleProject.name}-exploded.war")
  root(id: 'root') {
    println "Adding files to root"
    gradleProject.war.rootSpec.children.each {
      if (it.destPath.pathString.equals("")) {
        add(builder, it, "")
      }
    }
    println "Adding files to META-INF"
    element(id: 'directory', name: 'META-INF') {
      gradleProject.war.rootSpec.children.each {
        if (it.destPath.pathString.equals("META-INF")) {
          add(builder, it, "META-INF")
        }
      }
    }
    println "Adding files to WEB-INF"
    element(id: 'directory', name: 'WEB-INF') {
      element(id: 'file-copy', path: gradleProject.war.webXml)
      gradleProject.war.rootSpec.children.each {
        if (it.destPath.pathString.equals("WEB-INF")) {
          add(builder, it, "WEB-INF")
        }
      }
      Set<String> excludeJars = [] as Set
      element(id: 'directory', name: 'classes') {
        element(id: 'module-output', name: gradleProject.name)
        gradleProject.configurations.runtime.allDependencies.each {
          if (it.hasProperty('dependencyProject')) { 
            if (it.dependencyProject.hasProperty('jar'))
              excludeJars.add(it.dependencyProject.jar.archiveName)
            element(id: 'module-output', name: it.dependencyProject.name)
          }
        }
      }
      element(id: 'directory', name: 'lib') {
        gradleProject.configurations.runtime.each {
          if (!excludeJars.contains(it.name))
            element(id: 'file-copy', path: it)
        }
      }
    }
  }
}
artifactManager.append artifact

将add函数定义为：

def add(NodeBuilder builder, Object s, String dest, String prefix = "") {
  println(prefix + "current destination: [" + dest + "]")
  if (s instanceof File) {
    println(prefix + "-- file " + s.toString())
    builder.element(id: 'file-copy', path: s)
  } else if (s instanceof FileTree) {
    println(prefix + "-- folder " + s.dir.toString())
    builder.element(id: 'dir-copy', path: s.dir)
  } else if (s instanceof CopySpecInternal) {
    print(prefix + "-- copy spec " + s.toString() + " with destination path: [" + s.destPath.pathString + "]; ")
    if (dest.equals(s.destPath.pathString)) {
      println("destination matches current folder")
      s.sourcePaths.each { path ->
          add(builder, path, dest, prefix + "  ")
      }
      s.children.each { child -> add(builder, child, dest, prefix + "  ") }
    } else {
      println("")
      if (s.destPath.segments != null && s.destPath.segments.length > 0 && s.destPath.segments[0].equals(dest)) {
        String relDest = new RelativePath(false, Arrays.copyOfRange(s.destPath.segments, 1, s.destPath.segments.length)).pathString
        builder.element(id: 'directory', name: relDest) {
          s.sourcePaths.each { path ->
            add(builder, path, relDest, prefix + "  ")
          }
          s.children.each { child -> add(builder, child, relDest, prefix + "  ") }
        }
      } else {
        println(prefix + "!! destination path is not relative to [" + dest + "]: [" + s.destPath.pathString + "]")
      }
    }
  } else println(prefix + "?? unknown " + s.toString())
}

我基本上反向设计了war任务属性，并深入到要复制的文件树中。据我所知，这个任务没有公开一个接口来完成这类事情，所以我不得不求助于一个“讨厌”的解决方案，这不是我最喜欢的。如果有人能加些更干净的代码我会很高兴的。