用未解析文本对文本进行XSL转换为XML :需要更深入的内容

Question

我的格式相当好的输入(我不想复制所有数据)：

StartThing
Size Big
Colour Blue
coords 42, 42
foo bar
EndThing
StartThing
Size Small
Colour Red
coords 29, 51
machin bidule
EndThing
<!-- repeat a few thousand times-->

下面是我从Parse text file with XSLT修改的XSL

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:param name="text-encoding" as="xs:string" select="'iso-8859-1'"/>
    <xsl:param name="text-uri" as="xs:string" select="'unparsed-text.txt'"/>

    <xsl:template name="text2xml">
        <xsl:variable name="text" select="unparsed-text($text-uri, $text-encoding)"/>
        <xsl:analyze-string select="$text" regex="(Size|Colour|coords) (.+)">    
            <xsl:matching-substring>
                <xsl:element name="{(regex-group(1))}">
                    <xsl:value-of select="(regex-group(2))"/>
                </xsl:element>          
            </xsl:matching-substring>
        </xsl:analyze-string>
    </xsl:template>

    <xsl:template match="/">
        <xsl:call-template name="text2xml"/>    
    </xsl:template>
</xsl:stylesheet>

它可以很好地将对解析为元素和值。它给了我这个输出：

<?xml version="1.0" encoding="UTF-8"?>
<Size>Big</Size>
<Colour>Blue</Colour>
<coords>42, 42</coords>

但是，我也希望将值包装在Thing标记中，以便输出如下所示：

<Thing>
    <Size>Big</Size>
    <Colour>Blue</Colour>
    <coords>42, 42</coords>
</Thing>

一种解决方案可能是在每个“事物”之后匹配每组行的正则表达式。然后像我已经在做的那样匹配子串。还是有其他方法来解析树？

Answer 1

我将使用两个嵌套的analyze-string级别，一个外部级别来提取StartThing和EndThing之间的所有内容，然后使用内部级别对与外部级别匹配的字符串进行操作。

<xsl:template name="text2xml">
    <xsl:variable name="text" select="unparsed-text($text-uri, $text-encoding)"/>
    <!-- flags="s" allows .*? to match across newlines -->
    <xsl:analyze-string select="$text" regex="StartThing.*?EndThing" flags="s">
        <xsl:matching-substring>
            <Thing>
                <!-- "." here is the matching substring from the outer regex -->
                <xsl:analyze-string select="." regex="(Size|Colour|coords) (.+)">
                    <xsl:matching-substring>
                        <xsl:element name="{(regex-group(1))}">
                            <xsl:value-of select="(regex-group(2))"/>
                        </xsl:element>          
                    </xsl:matching-substring>
                </xsl:analyze-string>
            </Thing>
        </xsl:matching-substring>
    </xsl:analyze-string>
</xsl:template>