如何在基础操作系统露娜中向WingPanel添加状态图标？

Question

在初级操作系统露娜(或Ubuntu)中，如何将应用程序图标添加到WingPanel (桌面上显示状态图标(如Wi连接状态、声音属性以及日期和时间)的顶部？

​

​

我正在使用Vala编程语言。

Answer 1

过去在https://wiki.gnome.org/Projects/Vala/Examples页面上有一个处理添加托盘图标的例子，这可能会解决这个问题。我找不到那个链接，所以我将在这里提供源代码和编译命令。

using Gtk;

public class Main {

  class AppStatusIcon : Window {
    private StatusIcon trayicon;
    private Gtk.Menu menuSystem;

    public AppStatusIcon() {
      /* Create tray icon */
      trayicon = new StatusIcon.from_stock(Stock.HOME);
      trayicon.set_tooltip_text ("Tray");
      trayicon.set_visible(true);

      trayicon.activate.connect(about_clicked);

      create_menuSystem();
      trayicon.popup_menu.connect(menuSystem_popup);
    }

    /* Create menu for right button */
    public void create_menuSystem() {
      menuSystem = new Gtk.Menu();
      var menuAbout = new ImageMenuItem.from_stock(Stock.ABOUT, null);
      menuAbout.activate.connect(about_clicked);
      menuSystem.append(menuAbout);
      var menuQuit = new ImageMenuItem.from_stock(Stock.QUIT, null);
      menuQuit.activate.connect(Gtk.main_quit);
      menuSystem.append(menuQuit);
      menuSystem.show_all();
    }

    /* Show popup menu on right button */
    private void menuSystem_popup(uint button, uint time) {
      menuSystem.popup(null, null, null, button, time);
    }

    private void about_clicked() {
      var about = new AboutDialog();
      about.set_version("0.0.0");
      about.set_program_name("Tray");
      about.set_comments("Tray utility");
      about.set_copyright("vala");
      about.run();
      about.hide();
    }
  }

  public static int main (string[] args) {
    Gtk.init(ref args);
    var App = new AppStatusIcon();
    App.hide();
    Gtk.main();
    return 0;
  }
}

运行此命令的编译命令是：valac icon_test.vala -o build_test --pkg gtk+-3.0

我不确定这是否会以您想要的方式将它添加到面板中，但它确实创建了传统的托盘图标。祝好运。希望这能有所帮助。