首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >带有零的Stata表

问带有零的Stata表
EN

Stack Overflow用户
提问于 2013-10-29 06:37:43
回答 1查看 1.5K关注 0票数 1

我对斯塔塔和指挥部有意见:

代码语言:javascript
复制
svy: tab x

当给定的x没有观测值时。

我的问题是,当没有对类别的观察时,Stata简单地删除了相应的行。

我的任务是运行几个表格,并将关键结果保存并导出到csv文件中。有时,存储的向量有n个元素,而有时由于零,它们只有n-1元素,所以我不知道如何将它们合并到更大的矩阵中(或者至少将它们导出到一个有规则行距的文件中,如果没有观测值,则输出值为0)。我也试过

代码语言:javascript
复制
estpost svy, subpop(x0): tab x, count se format(%10.4g)

但我还是有同样的问题。

EN

回答 1

Stack Overflow用户

发布于 2013-11-01 23:49:06

更新3该解决方案基于estpost svy: tab,因为该命令返回比svy: tab本身更多可用的结果向量。与上一个版本一样,此解决方案将所有这些结果放入Stata数据集。它在求助于循环之前添加了一个检查数据是否包含缺失类别的检查,并稍微收紧了循环限制。按照Nick的建议,缺失值将替换所有与标准错误相关的统计数据。请注意,

代码语言:javascript
复制
 estpost svy: tab rep78

默认情况下,将估计的单元格比例放入e(b),将它们的标准错误放入e(se),而

代码语言:javascript
复制
 estpost svy: tab rep78, count

将估计的计数和它们的SE放入这些矩阵中。但是,其他摘要仍然可用,无论是在e(cell)还是e(count)中。

代码语言:javascript
复制
 sysuse auto, clear
 drop if rep78==2 |rep78==5

 svyset _n [pw = turn]
 estpost svy: tab rep78,  se

 /* Number categories from 1 to max */
 local maxcat = 5
 mata:
 /* count rows, add one for totals row
   assign the category for that row as .a */
 r = (st_matrix("e(Row)"), .a)'
 b = st_matrix("e(b)")'
 serr = st_matrix("e(se)")'
 lb = st_matrix("e(lb)")'
 ub = st_matrix("e(ub)")'
 def = st_matrix("e(deff)")'
 dft = st_matrix("e(deft)")'
 ct = st_matrix("e(count)")'
 pr = st_matrix("e(cell)")'
 obs = st_matrix("e(obs)")'
 d1 =(r , b, serr, lb, ub, def, dft, obs, pr, ct)

 /*  Where there are no totals, use a standard missing value */
 d1[rows(d1),3::7] = J(1,5, .)

 /* Check if there are no missing rows.
 If so, output the original returned matrices */
 if (`e(r)' ==`maxcat') d = d1
 /* Else create a zero matrix and populate it
 with statistics for the non-missing categories*/
 else {   
     d2= J(`maxcat',10,0)
     d2[.,1] =(1::`maxcat')
     for (j = 1; j<=`e(r)'; j++) {
        for (k = 1; k<=r[j,1]; k++) {
           if (r[j,1]== k) {
                   d2[k,2] = b[j,1]
                   d2[k,3] = serr[j,1]
                   d2[k,4] = lb[j,1]
                   d2[k,5] = ub[j,1]
                   d2[k,6] = def[j,1]
                   d2[k,7] = dft[j,1]
                   d2[k,8] = obs[j,1]
                   d2[k,9] = pr[j,1]
                   d2[k,10] = ct[j,1]
            }
        }
    }
 /* If rows are missing set SE-realated stats to missing*/
   for (k = 1; k<=`maxcat'; k++) {
      if (d2[k,2] == 0)  d2[k,3..7] =J(1,5,.)
    }
 /* Now add the totals row */
 d = d2 \ d1[rows(d1),.]
 }
 end
 clear
 getmata (rep78 b se lb ub deff deft nobs prop count ) = d
 format  b se lb ub deff deft prop  %5.2f
 format nobs count %10.0gc
 label define rtot  .a "Totals"
 label values rep78 rtot
 list
 save results, replace

原始答案这里有一种方法可以创建包含零类别的矩阵new。逻辑:设置一个零矩阵以保存所有类别的结果;然后用不缺少的categories.The宏的值替换零,maxcat包含表列变量的最大类别数。代码假定表变量中的类别是从1到maxcat的整数。mata块提取标准错误的向量,标量e(r)保存实际表中的行数。

代码语言:javascript
复制
 sysuse auto, clear
 svyset _n
 drop if rep78== 2 | rep78==5
 svy: tab rep78, count se

 local  maxcat = 5  //max no. of categories
 matrix  oldr = e(Row)'   // category values
 matrix ct = e(Obs)  // table counts

 // serr is a vector of std. errors
 mata: st_matrix("serr", sqrt(diagonal(st_matrix("e(V)"))))

 // matrix new  will hold the expanded results
 matrix new = J(`maxcat', 3, 0)

 forvalues j = 1/`=e(r)' {
 forvalues k = 1/`maxcat'{
 matrix new[`k',1] = `k'
 if oldr[`j',1]== `k'  {
 matrix new[`k',2] = ct[`j',1]
 matrix new[`k',3] = serr[`j',1]
 }
 }
 }
 matrix list new

更新2:这是一个在Mata中完成大部分工作的版本,然后将估计值保存到Stata数据集中。我稍微改变了矩阵的名字。

代码语言:javascript
复制
 sysuse auto, clear
 svyset _n
 drop if rep78== 2 | rep78==5
 svy: tab rep78, count se
 local maxcat =5

 mata:
 r = st_matrix("e(Row)")'
 ct = st_matrix("e(Obs)")
 serr= sqrt(diagonal(st_matrix("e(V)")))
 d = J(`maxcat',3,0)
 for (j = 1; j<=`e(r)'; j++) {
     for (k = 1; k<=`maxcat'; k++) {
         d[k,1] = k
         if (r[j,1]== k) {
            d[k,2] =   ct[j,1]
            d[k,3] = serr[j,1]
         }
    }
  }
 end
 clear
 getmata (rep78 count se) = d
 replace se = . if count==0
 format se %8.2f
 list
 save results, replace
票数 1
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/19651344

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档