使用XSL将graphML文件转换为另一个graphML？

Question

Hi有一个简单的graphML文件，由3个节点和2个连接组成，我想转换它，这样标记和属性的内部结构就有了不同的组织。

原始文件如下：

    <?xml version="1.0" encoding="utf-8"?><graphml xmlns="http://graphml.graphdrawing.org/xmlns" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://graphml.graphdrawing.org/xmlns http://graphml.graphdrawing.org/xmlns/1.0/graphml.xsd">
  <graph edgedefault="undirected">
    <node id="0">
      <data key="d0">rBSTS</data>
      <data key="d1" />
      <data key="d2" />
      <data key="d3">n1</data>
      <data key="d4" />
    </node>
    <node id="1">
      <data key="d1" />
      <data key="d4" />
      <data key="d0">rCAC</data>
      <data key="d2" />
      <data key="d3">n2</data>
    </node>
    <node id="2">
      <data key="d1" />
      <data key="d4" />
      <data key="d0">rCMF</data>
      <data key="d2" />
      <data key="d3">n3</data>
    </node>
     <edge source="0" target="1">
      <data key="d5">0.252829037184</data>
    </edge>
    <edge source="1" target="2">
      <data key="d5">0.205407183132</data>
    </edge>
 </graph>
</graphml>

虽然我想获得的文件如下(我手动转换它以显示所需的结果)：

<?xml version="1.0" encoding="UTF-8"?>
<graphml xmlns="http://graphml.graphdrawing.org/xmlns">

<graph edgedefault="undirected">

<node id="n1">
    <data key="dn_href"></data>
    <data key="dn_label">rBSTS</data>
    <data key="dn_free">rBSTS</data>
    <data key="dn_intensityvalue">1</data>
</node>
<node id="n2">
    <data key="dn_href"></data>
    <data key="dn_label">rCAC</data>
    <data key="dn_free">rCAC</data>
    <data key="dn_intensityvalue">2</data>
</node>
<node id="n3">
    <data key="dn_href"></data>
    <data key="dn_label">rCMF</data>
    <data key="dn_free">rCMF</data>
    <data key="dn_intensityvalue">3</data>
</node>
<edge id="e1_2" source="n1" target="n2">
    <data key="de_strength">0.252829037184</data>
</edge>
<edge id="e1_3" source="n2" target="n3">
    <data key="de_strength">0.205407183132</data>
</edge>
</graph>
</graphml>

结构的更改并不是那么容易(例如，原始数据结构中的节点ID从0开始，而在所需的输出中从n1开始)：是否可以使用XSL转换来转换它？

Answer 1

我对你想要的转换逻辑做了一些假设.

这个XSLT样式表：

<xsl:stylesheet version="1.0" 
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns:ns="http://graphml.graphdrawing.org/xmlns"
        xmlns="http://graphml.graphdrawing.org/xmlns"
        exclude-result-prefixes="ns #default">

  <xsl:output method="xml" 
          version="1.0" 
          indent="yes" 
          omit-xml-declaration="yes"/>

  <!-- The identity transform. By itself, copies out the original input. -->
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="ns:node">
    <!-- Copy out this element. -->
    <xsl:copy>
      <!-- Give it a new 'id' attribute that takes the value of the 'data'
       element for 'key' of 'd3'. -->
      <xsl:attribute name="id">
    <xsl:value-of select="ns:data[@key='d3']"/>
      </xsl:attribute>
      <!-- Output empty 'data' element for 'key' of 'dn_href'. -->
      <data key="dn_href"/>
      <!-- Do something particular for 'key' of 'd0'. -->
      <xsl:apply-templates select="ns:data[@key='d0']"/>
      <!-- Don't know where this value comes from! -->
      <data key="dn_intensity_value"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="ns:edge">
    <xsl:copy>
      <!-- Add an 'id' attribute. I'll let you work out what it 
       should be. -->
      <xsl:attribute name="id"/>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="ns:data[@key='d0']">
    <!-- It seems we want two 'data' elements, with different 'key's,
         and the text from the element with 'key' of 'd0'. -->
    <xsl:copy>
      <xsl:attribute name="key">dn_label</xsl:attribute>
      <xsl:apply-templates select="text()"/>
    </xsl:copy>
    <xsl:copy>
      <xsl:attribute name="key">dn_free</xsl:attribute>
      <xsl:apply-templates select="text()"/>
    </xsl:copy>
  </xsl:template>

  <!-- It seems 'd5' keys get changed to 'de_strength'. -->
  <xsl:template match="@key[. = 'd5']">
    <xsl:attribute name="key">
      <xsl:value-of select="'de_strength'"/>
    </xsl:attribute>
  </xsl:template>

  <!-- Mapping for source attributes. -->
  <xsl:template match="ns:edge/@source">
      <xsl:attribute name="source">
    <xsl:value-of select="//ns:node[@id=current()]/ns:data[@key='d3']"/>
      </xsl:attribute>
  </xsl:template>

  <!-- Mapping for target attributes. -->
  <xsl:template match="ns:edge/@target">
      <xsl:attribute name="target">
    <xsl:value-of select="//ns:node[@id=current()]/ns:data[@key='d3']"/>
      </xsl:attribute>
  </xsl:template>

</xsl:stylesheet>

当应用于示例输入时，将产生以下输出：

<graphml xmlns="http://graphml.graphdrawing.org/xmlns"
         xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
         xsi:schemaLocation="http://graphml.graphdrawing.org/xmlns http://graphml.graphdrawing.org/xmlns/1.0/graphml.xsd">
  <graph edgedefault="undirected">
      <node id="n1">
         <data key="dn_href"/>
         <data key="dn_label">rBSTS</data>
         <data key="dn_free">rBSTS</data>
         <data key="dn_intensity_value"/>
      </node>
      <node id="n2">
         <data key="dn_href"/>
         <data key="dn_label">rCAC</data>
         <data key="dn_free">rCAC</data>
         <data key="dn_intensity_value"/>
      </node>
      <node id="n3">
         <data key="dn_href"/>
         <data key="dn_label">rCMF</data>
         <data key="dn_free">rCMF</data>
         <data key="dn_intensity_value"/>
      </node>
      <edge id="" source="n1" target="n2">
         <data key="de_strength">0.252829037184</data>
      </edge>
      <edge id="" source="n2" target="n3">
         <data key="de_strength">0.205407183132</data>
      </edge>
  </graph>
</graphml>

正如您所看到的，它并不完美(额外的名称空间，缺少几个属性值)，但希望它向您展示您可能做的事情。