是否和如何避免Def吉循环中的eval

Question

在下面的代码中，人们是否应该避免eval？如果是这样的话，是怎么做的？或者这是一种特殊的情况，在这种情况下，使用eval更好吗？

(dolist (command '(....))
  (eval
   `(defadvice ,command (around blah activate)
      ...)))

以上成语的一个真实例子是：

(dolist (command '(paredit-comment-dwim comment-dwim))
  (eval
   `(defadvice ,command (around my-check-parens-and-warn-for-comment activate)
      (if (and (called-interactively-p 'any)
               (use-region-p))
          (progn
            (my-check-parens-and-warn-if-mismatch "You commented out a region and introduced a mismatched paren")
            ad-do-it
            (my-check-parens-and-warn-if-mismatch "You uncommented out a region and introduced a mismatched paren"))
        ad-do-it))))

Answer 1

有两种解决办法：

• 使用ad-add-advice而不是defadvice。
• 如果使用Emacs主干，可以使用新的advice-add。

使用advice-add的代码如下所示：

(defun my-check-commented-parens (orig-fun &rest args)
  (if (not (and (called-interactively-p 'any)
                (use-region-p)))
      (apply orig-fun args)
    (my-check-parens-and-warn-if-mismatch "You commented out a region and introduced a mismatched paren")
    (apply orig-fun args)
    (my-check-parens-and-warn-if-mismatch "You uncommented out a region and introduced a mismatched paren")))

(dolist (command '(paredit-comment-dwim comment-dwim))
  (advice-add command :around #'my-check-commented-parens))