在批处理文件中创建批处理文件- Echo ">NUL“

Question

形势：

• 我有一个经常更新的文本日志文件。
• 我已经有一个批处理文件，可以手动检查它。
• 我希望它(在批处理启动时)创建一个新的.bat。
• 我在导出/创建"timeOut /t 2 >NUL“部分时遇到问题。
• 它不会导出>NUL部分，只留下一个空白。
• 示例：timeout /t 2 /noBreak

我似乎想不出任何出口/回音的方法，那">NUL“片段。如有任何意见，将不胜感激！

echo mode con:cols=80 lines=28 >> %UserProfile%\Desktop\observeLog.bat
echo @echo off >> %UserProfile%\Desktop\observeLog.bat
echo Title Error Log >> %UserProfile%\Desktop\observeLog.bat
echo :startLogObserve >> %UserProfile%\Desktop\observeLog.bat
echo type %UserProfile%\Desktop\testLog.txt >> %UserProfile%\Desktop\observeLog.bat
echo timeout /t 2 >NUL /noBreak >> %UserProfile%\Desktop\observeLog.bat
echo cls >> %UserProfile%\Desktop\observeLog.bat
echo goTo :startLogObserve >> %UserProfile%\Desktop\observeLog.bat

Answer 1

您需要转义特殊字符，以便解析器知道要回显哪些部分，以及要执行哪些部分。

顺便说一句。重定向一个完整的块更容易

(
  echo mode con:cols=80 lines=28
  echo @echo off
  echo Title Error Log
  echo :startLogObserve
  echo type "%%UserProfile%%\Desktop\testLog.txt"
  echo timeout /t 2 ^>NUL /noBreak
  echo cls
  echo goTo :startLogObserve
) > %UserProfile%\Desktop\observeLog.bat

我还将type %UserProfile%..改为type "%%UserProfile%%..."，否则在observeLog.bat中得到扩展版本，当%UserProfile%包含空格或特殊字符时，引号很有用