FlowDocument到transformation如何在XSLT中选择前景颜色？

Question

我已经将XSLT从this answer中进行了调整并扩展到以下内容：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    exclude-result-prefixes="msxsl x">

  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

  <xsl:template match="x:Section[not(parent::x:Section)]">
    <div>
      <xsl:apply-templates select="node()"/>
    </div>
  </xsl:template>

  <xsl:template match="x:Section">
    <xsl:apply-templates select="node()"/>
  </xsl:template>

  <xsl:template match="x:Paragraph">
    <p>
      <xsl:apply-templates select="node()"/>
    </p>
  </xsl:template>

  <xsl:template match="x:Run">
    <xsl:variable name="style">
      <xsl:if test="@FontStyle='Italic'">
        <xsl:text>font-style:italic;</xsl:text>
      </xsl:if>
      <xsl:if test="@FontWeight='Bold'">
        <xsl:text>font-weight:bold;</xsl:text>
      </xsl:if>
      <xsl:if test="contains(@TextDecorations, 'Underline')">
        <xsl:text>text-decoration:underline;</xsl:text>
      </xsl:if>
      <xsl:if test="@FontSize != ''">
        <xsl:text>font-size:</xsl:text>
        <xsl:value-of select="@FontSize" />
        <xsl:text>pt;</xsl:text>
      </xsl:if>
      <xsl:if test="@FontFamily != ''">
        <xsl:text>font-family:</xsl:text>
        <xsl:value-of select="@FontFamily" />
        <xsl:text>;</xsl:text>
      </xsl:if>
      <xsl:if test="@Foreground-Color != ''">
        <xsl:text>color:</xsl:text>
        <xsl:value-of select="@Foreground-Color"/>
        <xsl:text>;</xsl:text>
      </xsl:if>
    </xsl:variable>
    <span>
      <xsl:if test="normalize-space($style) != ''">
        <xsl:attribute name="style">
          <xsl:value-of select="normalize-space($style)"/>
        </xsl:attribute>
      </xsl:if>
      <xsl:value-of select="text()"/>
    </span>
  </xsl:template>
</xsl:stylesheet>

除了这一部分之外，这个XSLT工作得很好：

  <xsl:if test="@Foreground-Color != ''">
    <xsl:text>color:</xsl:text>
    <xsl:value-of select="@Foreground-Color"/>
    <xsl:text>;</xsl:text>
  </xsl:if>

除了前景颜色，我尝试了颜色和FontColor，但似乎没有任何工作.

在"test=“和"select=”之后的正确关键字是什么来提取文本前景色？

Answer 1

当您使用CSS内联样式创建HTML时，它更多地是一个CSS问题而不是XSLT问题。CSS中正确的属性名确实是color，因此该部分是正确的。但是，我不知道输入格式所使用的颜色值，以及它们是否等于CSS所理解的颜色名称。因此，向我们展示输入的示例，并检查CSS颜色属性值规范：http://www.w3.org/TR/CSS2/syndata.html#value-def-color。

至于属性，基于http://msdn.microsoft.com/en-us/library/system.windows.documents.textelement.foreground.aspx，属性可能只是

  <xsl:if test="@Foreground != ''">
    <xsl:text>color:</xsl:text>
    <xsl:value-of select="@Foreground"/>
    <xsl:text>;</xsl:text>
  </xsl:if>

我还没有检查可能的颜色值及其与CSS值的匹配。