如何逆转行的顺序

Question

我试图在Excel工作表中编写一个宏，该宏将反转行的顺序，但不幸的是，我失败了。我甚至都不知道怎么开始。我将非常感谢任何帮助或提示如何做到这一点。

Answer 1

选择您的行并运行以下宏：

Sub ReverseList()
    Dim firstRowNum, lastRowNum, thisRowNum, lowerRowNum, length, count As Integer
    Dim showStr As String
    Dim thisCell, lowerCell As Range
    With Selection
        firstRowNum = .Cells(1).Row
        lastRowNum = .Cells(.Cells.count).Row
    End With
    showStr = "Going to reverse rows " & firstRowNum & " through " & lastRowNum
    MsgBox showStr

    showStr = ""
    count = 0
    length = (lastRowNum - firstRowNum) / 2
    For thisRowNum = firstRowNum To firstRowNum + length Step 1
        count = count + 1
        lowerRowNum = (lastRowNum - count) + 1
        Set thisCell = Cells(thisRowNum, 1)
        If thisRowNum <> lowerRowNum Then
            thisCell.Select
            ActiveCell.EntireRow.Cut
            Cells(lowerRowNum, 1).EntireRow.Select
            Selection.Insert
            ActiveCell.EntireRow.Cut
            Cells(thisRowNum, 1).Select
            Selection.Insert
        End If
        showStr = showStr & "Row " & thisRowNum & " swapped with " & lowerRowNum & vbNewLine
    Next
    MsgBox showStr
End Sub

如果您不喜欢通知，请注释掉MsgBox。

Answer 2

我对Wallys代码做了一些简化，并对其进行了修改，以便将行号作为输入参数：

Sub ReverseList(firstRowNum As Integer, lastRowNum As Integer)

  Dim upperRowNum, lowerRowNum, length As Integer

  length = (lastRowNum - firstRowNum - 2) / 2
  For upperRowNum = firstRowNum To firstRowNum + length Step 1
    lowerRowNum = lastRowNum - upperRowNum + firstRowNum

    Cells(upperRowNum, 1).EntireRow.Cut
    Cells(lowerRowNum, 1).EntireRow.Insert
    Cells(lowerRowNum, 1).EntireRow.Cut
    Cells(upperRowNum, 1).EntireRow.Insert
  Next
End Sub

托比

Answer 3

我用Range参数扩展了Tobag的答案，并使所有参数都是可选的：

Sub ReverseRows(Optional rng As range = Nothing, Optional firstRowNum As Long = 1, Optional lastRowNum As Long = -1)

    Dim i, firstRowIndex, lastRowIndex As Integer
    
    ' Set default values for dynamic parameters
    If rng Is Nothing Then Set rng = ActiveSheet.UsedRange
    If lastRowNum = -1 Then lastRowNum = rng.Rows.Count
    
    If firstRowNum <> 1 Then
        ' On each loop, cut the last row and insert it before row 1, 2, 3, and so on
        lastRowIndex = lastRowNum
        For i = firstRowNum To lastRowNum - 1 Step 1
            firstRowIndex = i
            rng.Rows(lastRowIndex).EntireRow.Cut
            rng.Rows(firstRowIndex).EntireRow.Insert
        Next
    Else
        ' Same as above, except handle different Insert behavior.
        ' When inserting to row 1, the insertion goes above/outside rng,
        ' thus the confusingly different indices.
        firstRowIndex = firstRowNum
        For i = firstRowNum To lastRowNum - 1 Step 1
            lastRowIndex = lastRowNum - i + 1
            rng.Rows(lastRowIndex).EntireRow.Cut
            rng.Rows(firstRowIndex).EntireRow.Insert
        Next
    End If
  
End Sub