一个未被拘留的符号的奇怪行为

Question

二进制文件是从包含以下定义的.lisp文件生成的：

 (in-package :xpto)

 (defmacro defparam (name init.value)  
     `(progn  
      (defvar ,name ,init.value)  
      (eval-when (:compile-toplevel :load-toplevel :execute)  
         (export ',name "xpto"))))  

  (defparam myparam 10)

  (defun getparam()
     myparam)

因此，我想创建一个补丁文件来覆盖这个符号，因此，我想到了这样的东西：

;; Unintern the given symbol because otherwise we are not able to overwrite it
;; once it was set through defvar
(eval-when (:compile-toplevel :load-toplevel :execute)  
             (unintern 'xpto::myparam :xpto))  

加载修补程序文件后，出现了奇怪的行为：

>  :pa xpto
>  myparam  
>> Error: Attempt to take the value of the unbound variable `myparam'

上面的输出正是我所期望的，但这一项却让我感到困扰：

>  (getparam)
>> 10

因为符号不再存在，所以我希望没有返回任何值。

如何删除/取消对myparam符号的任何引用都会返回上面显示的错误消息？

p.s:在修补程序文件中运行以下表达式对我来说不是一个有效的选项：

(setf myparam 20)

Answer 1

当您计算(defun getparam)时，它会记住符号myparam，每当您调用(getparam)时，它都会返回符号值。myparam的取消实习意味着您无法按名称在包中找到符号，但符号对象仍然存在。

(defvar myparam 10)
(defun getparam() myparam)
#'getparam
==> #<FUNCTION GETPARAM NIL ... (BLOCK GETPARAM MYPARAM)>
(unintern 'myparam)
#'getparam
==> #<FUNCTION GETPARAM NIL ... (BLOCK GETPARAM #:MYPARAM)>
(getparam)
==> 10

请注意，函数的第二个打印输出包含一个未嵌入的符号。

编辑

如何删除/取消对myparam符号的引用，以返回上面显示的错误消息？

除了重新定义getparam之外，没有其他方法。

但是，您可以不同地定义getparam：

(defvar myparam 10)
(defun getparam() 
  (symbol-value (or (find-symbol "MYPARAM") 
                    (error "Symbol MYPARAM does not exist"))))
(getparam)
==> 10
(unintern 'myparam)
(getparam)
*** - Symbol MYPARAM does not exist

Answer 2

您还可以使符号解除绑定：

CL-USER 4 > (defvar foosym 10)
FOOSYM

CL-USER 5 > foosym
10

CL-USER 6 > (makunbound 'foosym)
FOOSYM

CL-USER 7 > foosym

Error: The variable FOOSYM is unbound.