随机坡度点切线的求法

Question

我有一段被赋予的处理代码，它似乎正在设置一个随机傅里叶级数。不幸的是，尽管我努力提高我的数学技能，我不知道它在做什么，我发现文章没有多大帮助。

我试图扩展这段代码，这样我就可以在下面的代码创建的斜面上画一条切线。我能找到的最接近回答这个问题的是在数学论坛中。不幸的是，我并不真正理解正在讨论的是什么，或者它是否真的与我的情况相关。

任何帮助，我将如何去计算切线在这条曲线上的一个特定点，将是非常感谢。

更新截至06/17/13

我一直在玩这个，但没有成功。这是我所能做的最好的，而且我怀疑我是否正确地应用了导数来找到切线(或者即使我已经正确地找到了这个导数)。而且，我开始担心，即使其他一切都是正确的，我也没有正确地划定界限。如果有人能对此提供意见，我将不胜感激。

final int w = 800;
final int h = 480;
double[] skyline;
PImage img;
int numOfDeriv = 800;
int derivModBy = 1; //Determines how many points will be checked
int time;
int timeDelay = 1000;
int iter;
double[] derivatives;

void setup() {
  noStroke();
  size(w, h);
  fill(0,128,255);
  rect(0,0,w,h);
  int t[] = terrain(w,h);
  fill(77,0,0);
  for(int i=0; i < w; i++){
    rect(i, h, 1, -1*t[i]);
  }
  time = millis();
  timeDelay = 100;
  iter =0;
  img = get();
}

void draw() {
  int dnum = 0; //Current position of derivatives
  if(iter == numOfDeriv) iter = 0;
  if (millis() > time + timeDelay){
        image(img, 0, 0, width, height);
        strokeWeight(4);
        stroke(255,0,0);        
        point((float)iter*derivModBy, height-(float)skyline[iter*derivModBy]);
        strokeWeight(1);
        stroke(255,255,0);
        print("At x = ");
        print(iter);
        print(", y = ");
        print(skyline[iter]);
        print(", derivative = ");
        print((float)derivatives[iter]);
        print('\n');
        lineAngle(iter, (int)(height-skyline[iter]), (float)derivatives[iter], 100);
        lineAngle(iter, (int)(height-skyline[iter]), (float)derivatives[iter], -100);
        stroke(126);
        time = millis();
        iter += 1;
    }
}

void lineAngle(int x, int y, float angle, float length)
{
  line(x, y, x+cos(angle)*length, y-sin(angle)*length);
}

int[] terrain(int w, int h){

    width = w;
    height = h;

    //min and max bracket the freq's of the sin/cos series
    //The higher the max the hillier the environment
    int min = 1, max = 6;

    //allocating horizon for screen width
    int[] horizon = new int[width];
    skyline =  new double[width];
    derivatives = new double[numOfDeriv];

    //ratio of amplitude of screen height to landscape variation
    double r = (int) 2.0/5.0;

    //number of terms to be used in sine/cosine series
    int n = 4;

    int[] f = new int[n*2];

    //calculating omegas for sine series
    for(int i = 0; i < n*2 ; i ++){
      f[i] = (int) random(max - min + 1) + min;
    }

    //amp is the amplitude of the series
    int amp =  (int) (r*height);
    int dnum = 0; //Current number of derivatives    
    for(int i = 0 ; i < width; i ++){
      skyline[i] = 0;
      double derivative = 0.0;
      for(int j = 0; j < n; j++){
         if(i % derivModBy == 0){
            derivative += ( cos( (f[j]*PI*i/height) * f[j]*PI/height) - 
                        sin(f[j+n]*PI*i/height) * f[j+n]*PI/height);
         }

        skyline[i] += ( sin( (f[j]*PI*i/height) ) +  cos(f[j+n]*PI*i/height) );
        }
      skyline[i] *= amp/(n*2);
      skyline[i] += (height/2);
      skyline[i] = (int)skyline[i];
      horizon[i] = (int)skyline[i];
      derivative *= amp/(n*2);
      if(i % derivModBy == 0){
        derivatives[dnum++] = derivative;
        derivative = 0;
      }
    }

    return horizon;
}

void reset() {
  time = millis();
}

Answer 1

我收到了通过processing.org形式上的“夸克”回答这个问题。本质上，问题是，我取的是级数每个项的导数，而不是整个级数之和的导数。而且，我也没有正确地应用我的结果。

这是夸克的代码，只要它能解决这个问题。

final int w = 800;
final int h = 480;
float[] skyline;
PImage img;
int numOfDeriv = 800;
int derivModBy = 1; //Determines how many points will be checked
int time;
int timeDelay = 1000;
int iter;
float[] tangents;

public void setup() {
  noStroke();
  size(w, h);
  fill(0, 128, 255);
  rect(0, 0, w, h);
  terrain(w, h);
  fill(77, 0, 0);
  for (int i=0; i < w; i++) {
    rect(i, h, 1, -1*(int)skyline[i]);
  }
  time = millis();
  timeDelay = 100;
  iter =0;
  img = get();
}

public void draw() {
  if (iter == numOfDeriv) iter = 0;
  if (millis() > time + timeDelay) {
    image(img, 0, 0, width, height);
    strokeWeight(4);
    stroke(255, 0, 0);        
    point((float)iter*derivModBy, height-(float)skyline[iter*derivModBy]);
    strokeWeight(1);
    stroke(255, 255, 0);
    print("At x = ");
    print(iter);
    print(", y = ");
    print(skyline[iter]);
    print(", derivative = ");
    print((float)tangents[iter]);
    print('\n');
    lineAngle(iter, (int)(height-skyline[iter]), (float)tangents[iter], 100);
    lineAngle(iter, (int)(height-skyline[iter]), (float)tangents[iter], -100);
    stroke(126);
    time = millis();
    iter += 1;
  }
}

public void lineAngle(int x, int y, float angle, float length) {
  line(x, y, x+cos(angle)*length, y-sin(angle)*length);
}

public void terrain(int w, int h) {      
  //min and max bracket the freq's of the sin/cos series
  //The higher the max the hillier the environment
  int min = 1, max = 6;
  skyline =  new float[w];
  tangents = new float[w];
  //ratio of amplitude of screen height to landscape variation
  double r = (int) 2.0/5.0;
  //number of terms to be used in sine/cosine series
  int n = 4;
  int[] f = new int[n*2];
  //calculating omegas for sine series
  for (int i = 0; i < n*2 ; i ++) {
    f[i] = (int) random(max - min + 1) + min;
  }
  //amp is the amplitude of the series
  int amp =  (int) (r*h);
  for (int i = 0 ; i < w; i ++) {
    skyline[i] = 0;
    for (int j = 0; j < n; j++) {
      skyline[i] += ( sin( (f[j]*PI*i/h) ) +  cos(f[j+n]*PI*i/h) );
    }
    skyline[i] *= amp/(n*2);
    skyline[i] += (h/2);
  }
  for (int i = 1 ; i < w - 1; i ++) {
    tangents[i] = atan2(skyline[i+1] - skyline[i-1], 2);
  }
  tangents[0] = atan2(skyline[1] - skyline[0], 1);
  tangents[w-1] = atan2(skyline[w-2] - skyline[w-1], 1);
}

void reset() {
  time = millis();
}

Answer 2

在这个特殊的情况下，你不需要对傅里叶级数有太多的了解，只是它有这样的形式：

    A0 + A1*cos(x) + A2*cos(2*x) + A3*cos(3*x) +... + B1*sin(x) + B2*sin(x) +...

通常，您会得到一个函数f(x)，您需要找到An和Bn的值，这样Fourier级数就可以在某些区间[a, b]中收敛到您的函数(添加更多的项)。

然而，在这种情况下，他们想要一个看起来像不同的块和凹坑的随机函数(或者上下文可能建议的山丘和山谷)，所以他们从Fourier级数中选择了min和max之间的随机项，并将它们的系数设置为1(否则概念上为0)。它们还满足于一个由4个正弦项和4个余弦项组成的Fourier级数(这当然比无限多项更容易管理)。这意味着它们的Fourier级数看起来像不同频率的不同正弦和余弦函数相加(而且它们都有相同的振幅)。

如果您还记得以下几个方面的话，就很容易找到它的导数：

    sin(n*x)' = n * cos(x)
    cos(n*x)' = -n * sin(x)
    (f(x) + g(x))' = f'(x) + g'(x)

因此，计算导数的循环如下所示：

    for(int j = 0; j < n; j++){
        derivative += ( cos( (f[j]*PI*i/height) * f[j]*PI/height) - \
                        sin(f[j+n]*PI*i/height) * f[j+n]*PI/height);
    }

在某个时候，i (注意，导数是关于i的，因为它是代表我们在这里的x位置的变量)。

希望有了这个，你就能在i点上计算切线的方程了。

更新

在你做skyline[i] *= amp/(n*2);的时候，你也必须相应地调整你的导数，derivative *= amp/(n*2);，但是当你做skyline[i] += height/2;时，你的导数不需要调整