如何使用gfortran的加载库和getprocaddress？

Question

我正在学习如何从windows上的fortran可执行文件调用fortran中的函数。我正在使用gfortran 4.7和photran在eclipse中工作。

我的测试dll在hello.f90中只有一个函数：

hello.f90

subroutine hello
    implicit none
    print *, "Hello World!"
end subroutine hello

使用以下makefile：

all:
    gfortran -Wall -c hello.f90
    gfortran -shared -o hello.dll hello.o

Dependency确认函数"hello_“是导出的。

现在我正在构建一个动态调用它的程序。我根据我在网上找到的示例构建了以下内容，但它没有编译：

main.f90

program main
    implicit none
    integer :: p
    pointer (q, hello)
    p = loadlibrary("hello.dll")
    q = getprocaddress(p, "hello_")
    call hello
end program main

makefile

all:
    gfortran -Wall -pedantic -fcray-pointer main.f90 

错误消息是函数LoadLibrary (和getprocaddress)没有隐式类型。我怀疑这意味着那些函数没有被定义，我需要以某种方式包含它们的头。是那么回事吗？我在c:\mingw\include\winbase.h中为loadlibrary找到了一个声明

干杯,

Marc

Answer 1

LoadLibrary和GetProcAddress是Windows例程。与任何非内在函数一样，您需要声明这些函数的类型，并且考虑到这些API的性质，您还需要更进一步并提供完整的接口。

如果您正在为32位Windows进行编译，那么这些API使用的是stdcall调用约定。您需要使用gfortran源指令扩展来指定它。

(在64位Windows标准调用中，定义为与C调用约定相同--源指令没有任何效果。)

对于调用约定控件，如果我将DLL代码更改为：

SUBROUTINE hello() BIND(C, NAME='hello')
  IMPLICIT NONE
  PRINT *, 'Hello'
END SUBROUTINE hello

然后，下面的主程序将加载得到的DLL并执行该过程。

PROGRAM Main
  USE, INTRINSIC :: ISO_C_BINDING, ONLY:  &
      C_F_PROCPOINTER, C_FUNPTR, C_INTPTR_T,  &
      C_NULL_CHAR, C_CHAR, C_ASSOCIATED

  IMPLICIT NONE

  INTERFACE 
     FUNCTION LoadLibrary(lpFileName) BIND(C,NAME='LoadLibraryA')
        USE, INTRINSIC :: ISO_C_BINDING, ONLY: C_INTPTR_T, C_CHAR
        IMPLICIT NONE 
        CHARACTER(KIND=C_CHAR) :: lpFileName(*) 
        !GCC$ ATTRIBUTES STDCALL :: LoadLibrary 
        INTEGER(C_INTPTR_T) :: LoadLibrary 
     END FUNCTION LoadLibrary 

     FUNCTION GetProcAddress(hModule, lpProcName)  &
         BIND(C, NAME='GetProcAddress')
       USE, INTRINSIC :: ISO_C_BINDING, ONLY:  &
           C_FUNPTR, C_INTPTR_T, C_CHAR
       IMPLICIT NONE
       !GCC$ ATTRIBUTES STDCALL :: GetProcAddress
       TYPE(C_FUNPTR) :: GetProcAddress
       INTEGER(C_INTPTR_T), VALUE :: hModule
       CHARACTER(KIND=C_CHAR) :: lpProcName(*)
     END FUNCTION GetProcAddress      
  END INTERFACE

  ABSTRACT INTERFACE
    SUBROUTINE hello_intf() BIND(C)
      IMPLICIT NONE
    END SUBROUTINE hello_intf
  END INTERFACE

  INTEGER(C_INTPTR_T) :: module_handle
  TYPE(C_FUNPTR) :: proc_address
  PROCEDURE(hello_intf), BIND(C), POINTER :: my_proc

  !****      

  module_handle = LoadLibrary(C_CHAR_'hello.dll' // C_NULL_CHAR)
  IF (module_handle == 0) STOP 'Unable to load DLL'

  proc_address = GetProcAddress( module_handle,  &
      C_CHAR_'hello' // C_NULL_CHAR )
  IF (.NOT. C_ASSOCIATED(proc_address))  &
      STOP 'Unable to obtain procedure address'

  CALL C_F_PROCPOINTER(proc_address, my_proc)

  CALL my_proc

END PROGRAM Main